Palabras clave: deassign, force, release

La asignación continua procedimental es un tipo de asignación procedimental. Esta sentencia de asignación puede reemplazar todas las demás asignaciones de wire o reg, sobrescribiendo el valor actual de las variables de tipo wire o reg.

A diferencia de la asignación procedimental, la expresión de la asignación continua procedimental puede ser conducida continuamente a variables de tipo wire o reg. Es decir, cuando la asignación continua procedimental está en efecto, cualquier cambio en un operando de la expresión del lado derecho provocará la re-ejecución de la sentencia de asignación continua procedimental.

Hay principalmente dos tipos de asignación continua procedimental: assign-deassign y force-release.

assign, deassign

assign (operación de asignación procedimental) y deassign (cancelación de la operación de asignación procedimental) representan el primer tipo de sentencias de asignación continua procedimental. El objeto de la asignación solo puede ser un registro o un conjunto de registros, no una variable de tipo wire.

Durante la asignación, se asigna continuamente al registro; el valor en el registro se conserva hasta que se reasigna.

Por ejemplo, un flip-flop D con reset se puede describir con el siguiente código:

Ejemplo

module dff_normal(
    input       rstn,
    input       clk,
    input       D,
    output reg  Q
 );

    always @(posedge clk or negedge rstn) begin
        if(!rstn) begin   //Q = 0 after reset effective
            Q <= 1'b0 ;
        end
        else begin
            Q <= D ;       //Q = D at posedge of clock
        end
    end

endmodule  

A continuación, se reescribe con assign y deassign para realizar la misma función.

Es decir, cuando la señal de reset es 0, el terminal Q se asigna mediante la sentencia assign, y la salida siempre es 0.

Cuando la señal de reset es 1, el terminal Q se desasigna mediante la sentencia deassign, y se reasigna en el flanco de subida del reloj.

Ejemplo

module dff_assign(
    input       rstn,
    input       clk,
    input       D,
    output reg  Q
 );
 
    always @(posedge clk) begin
        Q <= D ;       //Q = D at posedge of clock
    end
 
    always @(negedge rstn) begin
        if(!rstn) begin
            assign Q = 1'b0 ; //change Q value when reset effective
        end
        else begin        //cancel the Q value overlay,
            deassign Q ;  //and Q remains 0-value until the coming of clock posedge
        end
    end
 
endmodule

force, release

force (operación de asignación forzada) y release (cancelación de la asignación forzada) representan el segundo tipo de sentencias de asignación continua procedimental.

El método de uso y el efecto son similares a assign y deassign, pero el objeto de la asignación puede ser una variable de tipo reg o una variable de tipo wire.

Debido a que es una asignación forzada incondicional, generalmente se usa en procesos de depuración interactiva; no debe usarse en módulos de diseño.

Cuando force actúa sobre un registro, el valor actual del registro se sobrescribe; al hacer release, el valor del registro conservará el valor que tenía durante la asignación forzada. Después, el valor de ese registro puede ser cambiado por la sentencia de asignación procedimental original.

Cuando force actúa sobre un net, el valor del net también se asigna forzosamente. Sin embargo, una vez que se hace release de esa variable de tipo net, su valor se convierte inmediatamente en el valor de conducción original.

Para observar de manera intuitiva la diferencia entre la asignación forzada de los dos tipos de variables, se utiliza el contador counter10 de la primera sección como módulo de diseño, y el testbench se diseña como sigue.

Ejemplo

`timescale 1ns/1ns
 
module test ;
    reg          rstn ;
    reg          clk ;
    reg [3:0]    cnt ;
    wire         cout ;
 
    counter10     u_counter (
        .rstn    (rstn),
        .clk     (clk),
        .cnt     (cnt),
        .cout    (cout));
 
    initial begin
        clk       = 0 ;
        rstn      = 0 ;
        #10 ;
        rstn      = 1'b1 ;
        wait (test.u_counter.cnt_temp == 4'd4) ;
        @(negedge clk) ;
        force     test.u_counter.cnt_temp = 4'd6 ;
        force     test.u_counter.cout     = 1'b1 ;
        #40 ;
        @(negedge clk) ;
        release   test.u_counter.cnt_temp ;
        release   test.u_counter.cout ;
    end
 
    initial begin
        clk = 0 ;
        forever #10 clk = ~ clk ;
    end
 
    //finish the simulation
    always begin
        #1000;
        if ($time >= 1000) $finish ;
    end
 
endmodule // test

Los resultados de la simulación son los siguientes.

Como se muestra en la figura, cuando cnt_temp es igual a 4 (80ns), cnt_temp se asigna forzosamente a 6 y cout se asigna forzosamente a 1.

Al hacer release (120ns), cnt_temp es de tipo registro y mantiene su valor original sin cambios; solo cuando el flanco de subida del reloj realiza la operación de asignación de suma, el valor cambia a 7.

Mientras que en 120ns, como cout es una variable de tipo net, su valor no puede conservarse. En el modelo counter10 del código original existe una sentencia de conducción:assign cout = (cnt_temp==4'd9), por lo que el valor de cout cambia a 0.

Descargar código fuente

Download