Palabras clave: instanciación, generate, sumador completo, acceso jerárquico

Referenciar otro módulo dentro de un módulo y conectar sus puertos correspondientemente se llama instanciación de módulos. La instanciación de módulos establece la jerarquía de la descripción. Los puertos de señales pueden asociarse por posición o por nombre, y las conexiones de puertos también deben seguir ciertas reglas.

Conexión de puertos por nombre

Este método conecta los puertos del módulo a instanciar con las señales externas según sus nombres. El orden de los puertos es arbitrario y puede no coincidir con el orden de declaración de puertos del módulo referenciado, siempre que los nombres de los puertos coincidan con las señales externas.

A continuación se muestra un ejemplo de instanciación de un sumador completo de 1 bit:

Ejemplo

full_adder1  u_adder0(
    .Ai     (a[0]),
    .Bi     (b[0]),
    .Ci     (c==1'b1 ? 1'b0 : 1'b1),
    .So     (so_bit0),
    .Co     (co_temp[0]));

Si algunos puertos de salida no necesitan conexión externa, durante la instanciación pueden dejarse flotantes (sin conectar) o incluso eliminarse. En general, los puertos input no pueden eliminarse durante la instanciación; de lo contrario, se producirá un error de compilación. Los puertos output sí pueden eliminarse durante la instanciación. Por ejemplo:

Ejemplo

//puerto de salida Co flotante
full_adder1  u_adder0(
    .Ai     (a[0]),
    .Bi     (b[0]),
    .Ci     (c==1'b1 ? 1'b0 : 1'b1),
    .So     (so_bit0),
    .Co     ());
 
//puerto de salida Co eliminado
full_adder1  u_adder0(
    .Ai     (a[0]),
    .Bi     (b[0]),
    .Ci     (c==1'b1 ? 1'b0 : 1'b1),
    .So     (so_bit0));

Conexión de puertos por orden

Este método conecta los puertos del módulo a instanciar con las señales externas según el orden en que se declararon los puertos en el módulo; la posición debe coincidir estrictamente. Por ejemplo, el código de instanciación de un sumador completo de 1 bit puede modificarse a:

full_adder1  u_adder1(
    a[1], b[1], co_temp[0], so_bit1, co_temp[1]);

Aunque este código puede ocupar relativamente menos espacio al escribirlo, la legibilidad del código disminuye y también es más difícil de depurar. A veces, en diseños grandes puede haber muchos puertos, y el orden de las señales de los puertos puede cambiar de vez en cuando. En ese caso, utilizar la conexión de puertos por orden para la instanciación de módulos resulta evidentemente inconveniente. Por lo tanto, se recomienda utilizar el método de puertos por nombre para instanciar módulos en la práctica.

Reglas de conexión de puertos

Puertos de entrada

Durante la instanciación de módulos, desde el exterior del módulo, los puertos input pueden conectarse a variables de tipo wire o reg. Esto es diferente de la declaración del módulo; desde el interior del módulo, los puertos input deben ser variables de tipo wire.

Puertos de salida

Durante la instanciación de módulos, desde el exterior del módulo, los puertos output deben conectarse a variables de tipo wire. Esto es diferente de la declaración del módulo; desde el interior del módulo, los puertos output pueden ser variables de tipo wire o reg.

Puertos de entrada y salida

Durante la instanciación de módulos, desde el exterior del módulo, los puertos inout deben conectarse a variables de tipo wire. Esto es igual que en la declaración del módulo.

Puertos flotantes

Durante la instanciación de módulos, si ciertas señales no necesitan conectarse o interactuar con señales externas, podemos dejarlas flotantes, es decir, dejar el espacio en blanco en el lugar de instanciación del puerto, como se mencionó en los ejemplos anteriores.

Cuando un puerto output se deja flotante normalmente, incluso podemos eliminarlo durante la instanciación.

Cuando un puerto input se deja flotante normalmente, la función lógica de la señal flotante se manifiesta como un estado de alta impedancia (valor lógico z). Sin embargo, durante la instanciación generalmente no se puede eliminar un puerto input flotante; de lo contrario, la compilación reportará un error. Por ejemplo:

Ejemplo

//El siguiente código generará una advertencia (Warning) al compilar
full_adder4  u_adder4(
    .a      (a),
    .b      (b),
    .c      (),
    .so     (so),
    .co     (co));

Ejemplo

//Si el módulo full_adder4 tiene un puerto input c, el siguiente código generará un Error al compilar
full_adder4  u_adder4(
    .a      (a),
    .b      (b),
    .so     (so),
    .co     (co));

En general, se recomienda no dejar flotantes los puertos input; cuando no tengan otras conexiones externas, asígneles un valor constante. Por ejemplo:

Ejemplo

full_adder4  u_adder4(
    .a      (a),
    .b      (b),
    .c      (1'b0),
    .so     (so),
    .co     (co));

Coincidencia de ancho de bits

Cuando el ancho de bits del puerto instanciado no coincide con el de la señal continua, el puerto se ajusta mediante alineación a la derecha o truncamiento de números sin signo.

Supongamos que en el módulo full_adder4, los puertos a y b tienen un ancho de 4 bits cada uno. Entonces, el resultado de instanciación del siguiente código provocará:u_adder4.a = {2'bzz, a[1:0]}, u_adder4.b = b[3:0] 。

Ejemplo

full_adder4  u_adder4(
    .a      (a[1:0]),      //input a[3:0]
    .b      (b[5:0]),      //input b[3:0]
    .c      (1'b0),
    .so     (so),
    .co     (co));

Tipos de señales continuas para puertos

Los tipos de señales que se conectan a los puertos pueden ser: 1) identificadores, 2) selección de bit, 3) selección parcial, 4) combinación de los tipos anteriores, 5) expresiones para puertos de entrada.

Por supuesto, los nombres de las señales pueden ser iguales a los nombres de los puertos, pero sus significados son diferentes; representan respectivamente señales dentro de 2 módulos distintos.

Uso de generate para la instanciación de módulos

Cuando se instancian múltiples módulos idénticos, instanciarlos uno por uno manualmente resulta engorroso. Usar la sentencia generate para la instanciación repetida de múltiples módulos puede simplificar enormemente el proceso de escritura del programa.

El código para instanciar repetidamente 4 sumadores completos de 1 bit para formar un sumador completo de 4 bits es el siguiente:

Ejemplo

module full_adder4(
    input [3:0]   a ,   //adder1
    input [3:0]   b ,   //adder2
    input         c ,   //input carry bit
 
    output [3:0]  so ,  //adding result
    output        co    //output carry bit
    );
 
    wire [3:0]    co_temp ;
    //El primer módulo instanciado generalmente tiene un formato diferente y debe instanciarse por separado
    full_adder1  u_adder0(
        .Ai     (a[0]),
        .Bi     (b[0]),
        .Ci     (c==1'b1 ? 1'b1 : 1'b0),
        .So     (so[0]),
        .Co     (co_temp[0]));
 
    genvar        i ;
    generate
        for(i=1; i<=3; i=i+1) begin: adder_gen
        full_adder1  u_adder(
            .Ai     (a[i]),
            .Bi     (b[i]),
            .Ci     (co_temp[i-1]), //El acarreo de salida del sumador completo anterior es el acarreo de entrada del siguiente
            .So     (so[i]),
            .Co     (co_temp[i]));
        end
    endgenerate
 
    assign co    = co_temp[3] ;
 
endmodule

El testbench es el siguiente:

Ejemplo

`timescale 1ns/1ns
 
module test ;
    reg  [3:0]   a ;
    reg  [3:0]   b ;
    //reg          c ;
    wire [3:0]   so ;
    wire         co ;
 
    //Control (driver) simple
    initial begin
        a = 4'd5 ;
        b = 4'd2 ;
        #10 ;
        a = 4'd10 ;
        b = 4'd8 ;
    end
 
    full_adder4  u_adder4(
               .a      (a),
               .b      (b),
               .c      (1'b0),   //Los puertos pueden conectarse a constantes
               .so     (so),
               .co     (co));
 
    initial begin
        forever begin
            #100;
            if ($time >= 1000)  $finish ;
        end
    end
 
endmodule // test

Los resultados de la simulación se muestran a continuación; se puede observar que el sumador completo de 4 bits funciona correctamente:

Acceso jerárquico

El nombre de cada módulo instanciado, las variables de señal de cada módulo, etc., se definen con un identificador específico. En todo el diseño jerárquico, cada identificador tiene una posición y un nombre únicos.

En Verilog, mediante el uso de una serie de.símbolos para separar y conectar jerárquicamente los identificadores de cada módulo, se puede acceder a los identificadores de todo el diseño desde cualquier lugar especificando el nombre jerárquico completo.

El acceso jerárquico se encuentra principalmente en la simulación.

Por ejemplo, con el siguiente diseño jerárquico, las señales entre las celdas hoja, los submódulos y el módulo de nivel superior pueden accederse mutuamente.

Ejemplo

//Acceder a las señales del módulo u_n3 desde el módulo u_n1:
a = top.u_m2.u_n3.c ;

//Acceder a las señales del módulo top desde el módulo u_n1
if (top.p == 'b0) a = 1'b1 ;

//Acceder a las señales del módulo u_n4 desde el módulo top
assign p = top.u_m2.u_n4.d ;

En las simulaciones de los capítulos anteriores, también se realizó acceso jerárquico relacionado, en mayor o menor medida. Por ejemplo"Asignación continua procedimental"En la sección correspondiente, se usaron las siguientes sentencias en el módulo de estímulo de simulación de nivel superior test:

wait (test.u_counter.cnt_temp == 4'd4) ;

Descarga del código fuente

Download