Palabras clave: while, for, repeat, forever

Las sentencias de bucle en Verilog tienen 4 tipos: bucles while, for, repeat y forever. Las sentencias de bucle solo pueden usarse dentro de bloques always o initial, pero pueden incluir expresiones de retardo.

Bucle while

La sintaxis del bucle while es la siguiente:

while (condition) begin
    …
end

La condición de terminación del bucle while es que condition sea falsa.

Si condition ya es falsa cuando se alcanza el bucle while al comenzar la ejecución, la sentencia del bucle no se ejecutará ni una vez.

Por supuesto, cuando solo hay una sentencia de ejecución, las palabras clave begin y end pueden omitirse.

Cuando se ejecuta el siguiente código, counter se ejecuta 11 veces.

Ejemplo

`timescale 1ns/1ns
 
module test ;
 
    reg [3:0]    counter ;
    initial begin
        counter = 'b0 ;
        while (counter<=10) begin
            #10 ;
            counter = counter + 1'b1 ;
        end
    end
 
   //stop the simulation
    always begin
        #10 ;  if ($time >= 1000) $finish ;
    end
 
endmodule

El resultado de la simulación es el siguiente:

Bucle for

La sintaxis del bucle for es la siguiente:

for(initial_assignment; condition ; step_assignment)  begin
    …
end

initial_assignment es la condición inicial.

condition es la condición de terminación; cuando condition es falsa, se sale inmediatamente del bucle.

step_assignment es la sentencia de asignación de proceso que cambia la variable de control, normalmente para incrementar o decrementar el contador de la variable de bucle.

En general, debido a que la condición inicial y las operaciones de auto-incremento ya están incluidas en el bucle for, la escritura del bucle for es más compacta que la del while, pero no en todos los casos se puede usar el bucle for para reemplazar al bucle while.

El siguiente ejemplo de bucle for logra el mismo efecto que el ejemplo del bucle while. Hay que tener en cuenta que i = i + 1 no puede escribirse como i++ como en C, y i = i - 1 tampoco puede escribirse como i--.

Ejemplo

// Sentencia de bucle for
integer      i ;
reg [3:0]    counter2 ;
initial begin
    counter2 = 'b0 ;
    for (i=0; i<=10; i=i+1) begin
        #10 ;
        counter2 = counter2 + 1'b1 ;
    end
end

Bucle repeat

La sintaxis del bucle repeat es la siguiente:

repeat (loop_times) begin
    …
end

La función de repeat es ejecutar un bucle un número fijo de veces; no puede usar una expresión lógica para determinar si el bucle continúa ejecutándose como el bucle while. El número de repeticiones del bucle repeat debe ser una constante, una variable o una señal. Si el número de repeticiones es una señal variable, el número de repeticiones es el valor de la señal variable al comenzar a ejecutarse el bucle repeat. Incluso si el valor de la señal variable que representa el número de repeticiones cambia durante la ejecución, el número de ejecuciones de repeat no cambiará.

El siguiente ejemplo de bucle repeat logra el mismo efecto que el ejemplo del bucle while.

Ejemplo

// Sentencia de bucle repeat
reg [3:0]    counter3 ;
initial begin
    counter3 = 'b0 ;
    repeat (11) begin  // Repetir 11 veces
        #10 ;
        counter3 = counter3 + 1'b1 ;
    end
end

El siguiente ejemplo de bucle repeat implementa la función de almacenar continuamente 8 datos:

Ejemplo

always @(posedge clk or negedge rstn) begin
    j = 0  ;
    if (!rstn) begin
        repeat (8) begin
            buffer[j]   <= 'b0 ;      // Asignación sin retardo, es decir, asignación simultánea a 0
            j = j + 1 ;
        end
    end
    else if (enable) begin
        repeat (8) begin
            @(posedge clk) buffer[j]    <= counter3 ;       // Asignar en el flanco ascendente del siguiente clk
            j = j + 1 ;
        end
     end
end

El resultado de la simulación se muestra en la siguiente figura.

Como se puede ver en la figura, cuando rstn se pone en alto, los 8 vectores de buffer se asignan simultáneamente a 0.

Después del segundo ciclo de reloj, buffer es asignado secuencialmente por counter3, implementando la función de almacenar continuamente 8 datos.

Bucle forever

La sintaxis del bucle forever es la siguiente:

forever begin
    …
end

La sentencia forever representa un bucle permanente, no contiene ninguna expresión de condición, y una vez que se ejecuta continúa ejecutándose infinitamente; la función de sistema $finish puede salir de forever.

forever equivale a while(1).

Normalmente, el bucle forever se utiliza junto con estructuras de control de tiempos.

Por ejemplo, usando la sentencia forever para generar un reloj:

Ejemplo

reg          clk ;
initial begin
    clk       = 0 ;
    forever begin
        clk = ~clk ;
        #5 ;
    end
end

Por ejemplo, usando la sentencia forever para implementar una transferencia de datos entre registros controlada por el flanco del reloj:

Ejemplo

reg    clk ;
reg    data_in, data_temp ;
initial begin
    forever @(posedge clk)      data_temp = data_in ;
end

Descargar código fuente

Download