Palabras clave: funciones, conversión big-endian/little-endian, decodificación de tubo digital
En Verilog, se pueden utilizar tareas (palabra clave: task) o funciones (palabra clave: function) para extraer diseños de nivel de comportamiento repetitivos y llamarlos en varios lugares, evitando así escribir código repetido múltiples veces y haciendo que el código sea más conciso y fácil de entender.
Función
Las funciones solo se pueden definir dentro de un módulo, en cualquier posición, y se pueden referenciar en cualquier lugar del módulo; su ámbito se limita a este módulo. Las funciones tienen principalmente las siguientes características:
- 1) No contienen ningún retardo, temporización ni lógica de control de temporización.
- 2) Tienen al menos una variable de entrada.
- 3) Solo tienen un valor de retorno y no tienen salidas.
- 4) No contienen asignaciones no bloqueantes.
- 5) Las funciones pueden llamar a otras funciones, pero no pueden llamar a tareas.
El formato de declaración de una función en Verilog es el siguiente:
function [range-1:0] function_id ; input_declaration ; other_declaration ; procedural_statement ; endfunction
Al declarar una función, se declara implícitamente una variable de registro con ancho range y nombre function_id; el valor de retorno de la función se pasa a través de esta variable. Cuando la variable de registro no tiene un ancho especificado, el ancho por defecto es 1.
La función se llama especificando el nombre de la función y las variables de entrada. Cuando la función termina, el valor de retorno se transfiere al lugar de la llamada.
El formato de llamada de la función es el siguiente:
function_id(input1, input2, …);
A continuación se utiliza una función para implementar la conversión de endianness (big-endian/little-endian) de datos.
Cuando la entrada es 4'b0011, la salida puede ser 4'b1100. Por ejemplo:
Ejemplo
#(parameter N = 4)
(
input en, //enable control
input [N-1:0] a ,
output [N-1:0] b
);
reg [N-1:0] b_temp ;
always @(*) begin
if (en) begin
b_temp = data_rvs(a);
end
else begin
b_temp = 0 ;
end
end
assign b = b_temp ;
//function entity
function [N-1:0] data_rvs ;
input [N-1:0] data_in ;
parameter MASK = 32'h3 ;
integer k ;
begin
for(k=0; k<N; k=k+1) begin
data_rvs[N-k-1] = data_in[k] ;
end
end
endfunction
endmodule
Los parámetros dentro de la función también se pueden modificar, por ejemplo:
defparam data_rvs.MASK = 32'd7 ;
Sin embargo, durante la simulación se descubrió que esta forma de escritura puede pasar la compilación, pero en los resultados de la simulación, el parámetro MASK dentro de la función en realidad no se modificó con éxito, y sigue siendo 32'h3. Esto puede estar relacionado con el compilador; los interesados pueden experimentar con otros compiladores de Verilog.
Al declarar una función, también se puede agregar un paréntesis después del nombre de la función para encerrar las declaraciones input.
Por ejemplo, la función de conversión de endianness mencionada anteriormente se puede expresar como:
function [N-1:0] data_rvs(
input [N-1:0] data_in
......
) ;
Función constante
Una función constante es una función cuyo resultado se calcula como constante durante la compilación, antes de que comience la simulación. Las funciones constantes no permiten acceder a variables globales ni llamar a funciones del sistema, pero pueden llamar a otra función constante.
Este tipo de función se puede utilizar para referenciar valores complejos, por lo que se puede usar en lugar de constantes.
Por ejemplo, la siguiente función constante se puede utilizar para calcular el ancho del bus de direcciones en el módulo:
Ejemplo
reg [logb2(MEM_DEPTH)-1: 0] addr ; // Se obtiene que el ancho de addr es de 8 bits.
function integer logb2;
input integer depth ;
// 256 es 9 bits; nuestro dato final debería ser 8, por lo que necesitamos detener el bucle anticipadamente cuando depth=2.
for(logb2=0; depth>1; logb2=logb2+1) begin
depth = depth >> 1 ;
end
endfunction
Función automatic
En Verilog, las variables locales de las funciones normales son estáticas, es decir, cada llamada a la función usa el mismo espacio de almacenamiento para sus variables locales. Si una función se llama de forma concurrente en dos lugares diferentes, ambas llamadas a la función operan sobre la misma dirección al mismo tiempo, lo que puede provocar resultados indeterminados.
Verilog utiliza la palabra clave automatic para declarar este tipo de funciones, que pueden asignar automáticamente nuevo espacio de memoria al ser llamadas; también se pueden entender como recursivas. Por lo tanto, las variables locales declaradas en una función automatic no se pueden acceder mediante nombres jerárquicos, pero la función automatic en sí se puede llamar mediante nombres jerárquicos.
A continuación se utiliza una función automatic para implementar el cálculo factorial:
Ejemplo
function automatic integer factorial ;
input integer data ;
integer i ;
begin
factorial = (data>=2)? data * factorial(data-1) : 1 ;
end
endfunction // factorial
A continuación se muestran los resultados de simulación con la palabra clave automatic y sin la palabra clave automatic.
Como se puede ver en la figura, la señal results3 ha obtenido el resultado deseado, es decir, el factorial de 4.
Mientras que la señal results_noauto tiene un valor de 1, que no es un resultado normal predecible; aquí no se hará un análisis inútil.

Decodificación de tubo digital
Los conocimientos relacionados con funciones mencionados anteriormente no parecen mostrar la superioridad de las funciones. A continuación se diseña un decodificador de tubo digital de 4 dígitos decimales para ilustrar la ventaja de que las funciones pueden simplificar el código.
La siguiente figura es una imagen real de un tubo digital (display de 7 segmentos), que se puede utilizar para mostrar números decimales de 4 dígitos. Tiene aplicaciones bastante extendidas en áreas como la puntuación de competiciones y el cronometraje.

Cada dígito del display tiene 8 terminales de control de iluminación (como se muestra en la figura, a-g), que se utilizan para controlar la visualización de los números 0-9.
El tubo digital tiene 4 selecciones de chip (como 1-4 en la figura), que controlan qué dígito del display debe estar activado, es decir, debe iluminarse. Si en un período muy corto de tiempo se activan secuencialmente los 4 dígitos del display para que emitan luz, mientras se proporcionan diferentes controles de iluminación bajo diferentes selecciones de chip (correspondientes a los 4 dígitos decimales), entonces, cuando el ojo humano no puede distinguirlo, se logra el efecto de mostrar 4 dígitos decimales simultáneamente.

A continuación, utilizamos la señal abcdefg para controlar los terminales de control de iluminación, la señal csn para controlar la selección de chip, y los dígitos de unidades, decenas, centenas y miles del número decimal de 4 dígitos se representan respectivamente con las señales de 4 bits single_digit, ten_digit, hundred_digit y kilo_digit. Entonces, el diseño de visualización de un tubo digital se puede describir de la siguiente manera:
Ejemplo
(
input clk ,
input rstn ,
input en ,
input [3:0] single_digit ,
input [3:0] ten_digit ,
input [3:0] hundred_digit ,
input [3:0] kilo_digit ,
output reg [3:0] csn , //chip select, low-available
output reg [6:0] abcdefg //light control
);
reg [1:0] scan_r ; //scan_ctrl
always @ (posedge clk or negedge rstn) begin
if(!rstn)begin
csn <= 4'b1111;
abcdefg <= 'd0;
scan_r <= 3'd0;
end
else if (en) begin
case(scan_r)
2'd0:begin
scan_r <= 3'd1;
csn <= 4'b0111; //select single digit
abcdefg <= dt_translate(single_digit);
end
2'd1:begin
scan_r <= 3'd2;
csn <= 4'b1011; //select ten digit
abcdefg <= dt_translate(ten_digit);
end
2'd2:begin
scan_r <= 3'd3;
csn <= 4'b1101; //select hundred digit
abcdefg <= dt_translate(hundred_digit);
end
2'd3:begin
scan_r <= 3'd0;
csn <= 4'b1110; //select kilo digit
abcdefg <= dt_translate(kilo_digit);
end
endcase
end
end
/*------------ translate function -------*/
function [6:0] dt_translate;
input [3:0] data;
begin
case(data)
4'd0: dt_translate = 7'b1111110; //number 0 -> 0x7e
4'd1: dt_translate = 7'b0110000; //number 1 -> 0x30
4'd2: dt_translate = 7'b1101101; //number 2 -> 0x6d
4'd3: dt_translate = 7'b1111001; //number 3 -> 0x79
4'd4: dt_translate = 7'b0110011; //number 4 -> 0x33
4'd5: dt_translate = 7'b1011011; //number 5 -> 0x5b
4'd6: dt_translate = 7'b1011111; //number 6 -> 0x5f
4'd7: dt_translate = 7'b1110000; //number 7 -> 0x70
4'd8: dt_translate = 7'b1111111; //number 8 -> 0x7f
4'd9: dt_translate = 7'b1111011; //number 9 -> 0x7b
endcase
end
endfunction
endmodule
Los resultados de la simulación son los siguientes.
Como se puede ver en la figura, las señales de selección de chip, decodificación, etc., cumplen con el diseño. En la práctica, los 4 dígitos deben permanecer sin cambios durante un cierto período de tiempo, mientras la señal de selección de chip escanea cíclicamente sin detenerse, para que el tubo digital presente un efecto de visualización estática al ojo humano.

Resumen
Si el diseño del decodificador no utilizara la función dt_translate, entonces al asignar la señal abcdefg en cada opción del case, también sería necesario evaluar single_digit, ten_digit, hundred_digit y kilo_digit. Estas sentencias de evaluación se repetirían 4 veces. Aunque el circuito de hardware real sintetizado al final pueda ser el mismo, es evidente que el código que utiliza funciones es más conciso y legible.
Descarga del código fuente
Download