Schlüsselwörter: Funktionen, Endian-Konvertierung, Siebensegmentanzeige-Dekodierung
In Verilog können Tasks (Schlüsselwort: task) oder Funktionen (Schlüsselwort: function) verwendet werden, um sich wiederholende Entwürfe auf Verhaltensebene zu extrahieren und sie an mehreren Stellen aufzurufen, wodurch das wiederholte Schreiben von doppeltem Code vermieden wird und der Code prägnanter und leichter verständlich wird.
Funktion
Funktionen können nur in einem Modul definiert werden, an beliebiger Stelle, und können überall innerhalb des Moduls referenziert werden; ihr Gültigkeitsbereich ist ebenfalls auf dieses Modul beschränkt. Funktionen haben hauptsächlich die folgenden Eigenschaften:
- 1) Sie enthalten keinerlei Verzögerungen, Timing- oder Zeitsteuerungslogik.
- 2) Sie haben mindestens eine Eingangsvariable.
- 3) Sie haben nur einen Rückgabewert und keinen Ausgang.
- 4) Sie enthalten keine nicht blockierenden Zuweisungsanweisungen.
- 5) Funktionen können andere Funktionen aufrufen, aber keine Tasks aufrufen.
Das Format der Verilog-Funktionsdeklaration ist wie folgt:
function [range-1:0] function_id ; input_declaration ; other_declaration ; procedural_statement ; endfunction
Wenn eine Funktion deklariert wird, wird implizit eine Registervariable mit Breitenbereich und dem Namen function_id deklariert, und der Rückgabewert der Funktion wird über diese Variable übergeben. Wenn für diese Registervariable keine Breite angegeben ist, beträgt die Standardbreite 1.
Funktionen werden aufgerufen, indem der Funktionsname und die Eingabevariablen angegeben werden. Wenn die Funktion endet, wird der Rückgabewert an die aufrufende Stelle übergeben.
Das Format des Funktionsaufrufs ist wie folgt:
function_id(input1, input2, …);
Nachfolgend wird eine Funktion verwendet, um die Daten-Endian-Konvertierung zu implementieren.
Wenn die Eingabe 4'b0011 ist, kann die Ausgabe 4'b1100 sein. Zum Beispiel:
Beispiel
#(Parameter N = 4)
(
input en, //Freigabesteuerung
input [N-1:0] a ,
output [N-1:0] b
);
reg [N-1:0] b_temp ;
always @(*) begin
if (en) begin
b_temp = data_rvs(a);
end
else begin
b_temp = 0 ;
end
end
assign b = b_temp ;
//Funktionsentität
function [N-1:0] data_rvs ;
input [N-1:0] data_in ;
parameter MASK = 32'h3 ;
integer k ;
begin
for(k=0; k<N; k=k+1) begin
data_rvs[N-k-1] = data_in[k] ;
end
end
endfunction
endmodule
Parameter in einer Funktion können ebenfalls geändert werden, zum Beispiel:
defparam data_rvs.MASK = 32'd7 ;
Allerdings zeigt die Simulation, dass diese Schreibweise erfolgreich kompiliert, aber in den Simulationsergebnissen wird der Parameter MASK in der Funktion tatsächlich nicht erfolgreich geändert und bleibt 32'h3. Dies kann mit dem Compiler zusammenhängen. Interessierte Wissenschaftler können mit anderen Verilog-Compilern experimentieren.
Beim Deklarieren einer Funktion kann man auch Klammern nach dem Funktionsnamen hinzufügen, um die Eingabedeklarationen einzuschließen.
Beispielsweise kann die obige Deklarationsfunktion für die Endian-Konvertierung wie folgt ausgedrückt werden:
function [N-1:0] data_rvs(
input [N-1:0] data_in
......
) ;
Konstantenfunktion
Eine Konstantenfunktion ist eine Funktion, deren Ergebnis während der Kompilierung vor Beginn der Simulation als Konstante berechnet wird. Konstantenfunktionen dürfen nicht auf globale Variablen zugreifen oder Systemfunktionen aufrufen, aber sie können andere Konstantenfunktionen aufrufen.
Solche Funktionen können verwendet werden, um komplexe Werte zu referenzieren, sodass sie zum Ersetzen von Konstanten verwendet werden können.
Beispielsweise kann die folgende Konstantenfunktion verwendet werden, um die Breite des Adressbusses in einem Modul zu berechnen:
Beispiel
reg [logb2(MEM_DEPTH)-1: 0] addr ; //Die Breite von addr lässt sich als 8 Bits ermitteln
function integer logb2;
input integer depth ;
//256 ist 9 Bits, unsere endgültigen Daten sollten 8 sein, also muss die Schleife frühzeitig beendet werden, wenn depth=2
for(logb2=0; depth>1; logb2=logb2+1) begin
depth = depth >> 1 ;
end
endfunction
automatic function
In Verilog sind die lokalen Variablen gewöhnlicher Funktionen statisch, was bedeutet, dass jeder Aufruf der Funktion denselben Speicherplatz für ihre lokalen Variablen verwendet. Wenn eine Funktion an zwei verschiedenen Stellen gleichzeitig aufgerufen wird, arbeiten die beiden Funktionsaufrufe gleichzeitig auf derselben Adresse, was zu unbestimmten Funktionsergebnissen führt.
Verilog verwendet das Schlüsselwort automatic, um Funktionen zu beschreiben. Solche Funktionen können beim Aufruf automatisch neuen Speicherplatz zuweisen, was auch als rekursiv verstanden werden kann. Daher kann auf lokale Variablen, die in einer automatic-Funktion deklariert sind, nicht durch hierarchische Benennung zugegriffen werden, aber die automatic-Funktion selbst kann über einen hierarchischen Namen aufgerufen werden.
Nachfolgend wird eine automatic-Funktion verwendet, um die Fakultätsberechnung zu implementieren:
Beispiel
function automatic integer factorial ;
input integer data ;
integer i ;
begin
factorial = (data>=2)? data * factorial(data-1) : 1 ;
end
endfunction // factorial
Das Folgende sind die Simulationsergebnisse mit und ohne das Schlüsselwort automatic.
Aus der Abbildung ist ersichtlich, dass das Signal results3 das gewünschte Ergebnis erzielt hat, nämlich die Fakultät von 4.
Das Signal results_noauto hat den Wert 1, was kein vorhersehbares normales Ergebnis ist, daher wird hier keine weitere nutzlose Analyse durchgeführt.

Dekodierung einer Siebensegmentanzeige
Das oben behandelte Wissen über Funktionen scheint die Vorteile von Funktionen nicht zu veranschaulichen. Im Folgenden wird ein 4-stelliger Dezimal-Siebensegmentanzeige-Decoder entworfen, um den Vorteil zu veranschaulichen, dass Funktionen Code vereinfachen können.
Die folgende Abbildung ist eine physische Darstellung einer Siebensegmentanzeige, mit der 4-stellige Dezimalzahlen angezeigt werden können. Sie wird in recht großem Umfang bei der Wettkampfwertung, Zeitmessung und in anderen Bereichen eingesetzt.

Jedes Ziffernanzeigesegment hat 8 Lichtsteueranschlüsse (wie in der Abbildung durch a-g dargestellt), mit denen die Anzeige der Ziffern 0-9 gesteuert werden kann.
Die Siebensegmentanzeige verfügt über 4 Chip-Selects (in der Abbildung als 1-4 dargestellt), mit denen gesteuert wird, welche Ziffernanzeigestelle ausgewählt werden soll, d. h. welche leuchten soll. Wenn die 4 Ziffernanzeigesegmente in einer sehr kurzen Zeit nacheinander ausgewählt und zum Leuchten gebracht werden, während unter verschiedenen Chip-Selects unterschiedliche Leuchtsteuerungen ausgegeben werden (jeweils entsprechend den 4 Dezimalziffern), dann wird im Rahmen dessen, was das menschliche Auge unterscheiden kann, der Effekt erzielt, dass 4 Dezimalziffern gleichzeitig angezeigt werden.

Im Folgenden verwenden wir das Signal abcdefg zur Steuerung der Lichtsteuerungsanschlüsse und das Signal csn zur Steuerung der Chipauswahl. Die Einer-, Zehner-, Hunderter- und Tausenderstellen der 4-stelligen Dezimalzahl werden durch vier 4-Bit-Signale single_digit, ten_digit, hundred_digit bzw. kilo_digit dargestellt. Das Anzeigedesign einer Siebensegmentanzeige kann wie folgt beschrieben werden:
Beispiel
(
input clk ,
input rstn ,
input en ,
input [3:0] single_digit ,
input [3:0] ten_digit ,
input [3:0] hundred_digit ,
input [3:0] kilo_digit ,
output reg [3:0] csn , //Chipauswahl, low-aktiv
output reg [6:0] abcdefg //Lichtsteuerung
);
reg [1:0] scan_r ; //scan_ctrl
always @ (posedge clk or negedge rstn) begin
if(!rstn)begin
csn <= 4'b1111;
abcdefg <= 'd0;
scan_r <= 3'd0;
end
else if (en) begin
case(scan_r)
2'd0:begin
scan_r <= 3'd1;
csn <= 4'b0111; //Einerstelle auswählen
abcdefg <= dt_translate(single_digit);
end
2'd1:begin
scan_r <= 3'd2;
csn <= 4'b1011; //Zehnerstelle auswählen
abcdefg <= dt_translate(ten_digit);
end
2'd2:begin
scan_r <= 3'd3;
csn <= 4'b1101; //Hunderterstelle auswählen
abcdefg <= dt_translate(hundred_digit);
end
2'd3:begin
scan_r <= 3'd0;
csn <= 4'b1110; //Tausenderstelle auswählen
abcdefg <= dt_translate(kilo_digit);
end
endcase
end
end
/*------------ Übersetzungsfunktion -------*/
function [6:0] dt_translate;
input [3:0] data;
begin
case(data)
4'd0: dt_translate = 7'b1111110; //Nummer 0 -> 0x7e
4'd1: dt_translate = 7'b0110000; //Nummer 1 -> 0x30
4'd2: dt_translate = 7'b1101101; //Nummer 2 -> 0x6d
4'd3: dt_translate = 7'b1111001; //Nummer 3 -> 0x79
4'd4: dt_translate = 7'b0110011; //Nummer 4 -> 0x33
4'd5: dt_translate = 7'b1011011; //Nummer 5 -> 0x5b
4'd6: dt_translate = 7'b1011111; //Nummer 6 -> 0x5f
4'd7: dt_translate = 7'b1110000; //Nummer 7 -> 0x70
4'd8: dt_translate = 7'b1111111; //Nummer 8 -> 0x7f
4'd9: dt_translate = 7'b1111011; //Nummer 9 -> 0x7b
endcase
end
endfunction
endmodule
Die Simulationsergebnisse sind wie folgt.
Aus der Abbildung ist ersichtlich, dass Signale wie Chip-Select und Decodierung alle dem Entwurf entsprechen. In der Praxis sollten die 4 Ziffern für einen bestimmten Zeitraum unverändert bleiben, während das Chip-Select-Signal kontinuierlich in einer Schleife scannt, sodass die Siebensegmentanzeige für das menschliche Auge einen statischen Anzeigeeffekt bietet.

Zusammenfassung
Wenn der Decoder-Entwurf die Funktion dt_translate nicht verwenden würde, dann wäre es beim Zuweisen des Signals abcdefg in jeder case-Option auch notwendig, single_digit, ten_digit, hundred_digit und kilo_digit zu überprüfen. Diese Überprüfungsanweisungen würden 4-mal wiederholt. Obwohl die tatsächliche Hardware-Schaltung, die am Ende synthetisiert wird, dieselbe sein kann, ist es offensichtlich, dass der Code unter Verwendung von Funktionen prägnanter und lesbarer ist.
Quellcode-Download
Herunterladen