Schlüsselwörter: if, selector

Bedingte Anweisungen

Bedingte (if-)Anweisungen werden verwendet, um zu steuern, ob Ausführungsanweisungen basierend auf der Auswertung von Bedingungen ausgeführt werden.

Bedingte Anweisungen werden mit den Schlüsselwörtern if und else deklariert, und der Bedingungsausdruck muss in Klammern eingeschlossen werden.

Die Verwendungsstruktur von bedingten Anweisungen wird wie folgt beschrieben:

if (condition1)       true_statement1 ;
else if (condition2)        true_statement2 ;
else if (condition3)        true_statement3 ;
else                      default_statement ;
  • Wenn die if-Anweisung ausgeführt wird, wird true_statement1 ausgeführt, wenn condition1 wahr ist; wenn condition1 falsch und condition2 wahr ist, wird true_statement2 ausgeführt; und so weiter.
  • Die else if- und else-Strukturen können weggelassen werden; das heißt, eine einzelne if-Bedingungsprüfung und eine Gruppe von Ausführungsanweisungen, true_statement1, können einen Ausführungsprozess bilden.
  • Mehrere else if-Klauseln können verkettet werden, nicht auf nur 1 oder 2 beschränkt.
  • Ausführungsanweisungen wie true_statement1 können eine einzelne Anweisung oder mehrere Anweisungen sein. Wenn mehrere Ausführungsanweisungen vorhanden sind, müssen sie mit den Schlüsselwörtern begin und end eingeschlossen werden.

Der folgende Code implementiert einen 4-zu-1-Selektor.

Beispiel

module mux4to1(
    input [1:0]     sel ,
    input [1:0]     p0 ,
    input [1:0]     p1 ,
    input [1:0]     p2 ,
    input [1:0]     p3 ,
    output [1:0]    sout);

    reg [1:0]     sout_t ;

    always @(*) begin
        if (sel == 2'b00)
            sout_t = p0 ;
        else if (sel == 2'b01)
            sout_t = p1 ;
        else if (sel == 2'b10)
            sout_t = p2 ;
        else
            sout_t = p3 ;
    end
    assign sout = sout_t ;
 
endmodule

Der Testbench-Code ist wie folgt:

Beispiel

`timescale 1ns/1ns

module test ;
    reg [1:0]    sel ;
    wire [1:0]   sout ;

    initial begin
        sel       = 0 ;
        #10 sel   = 3 ;
        #10 sel   = 1 ;
        #10 sel   = 0 ;
        #10 sel   = 2 ;
    end

    mux4to1 u_mux4to1 (
        .sel    (sel),
        .p0     (2'b00),        //path0 wird 0 zugewiesen
        .p1     (2'b01),        //path1 wird 1 zugewiesen
        .p2     (2'b10),        //path2 wird 2 zugewiesen
        .p3     (2'b11),        //path3 wird 3 zugewiesen
        .sout   (sout));

   //Simulation beenden
    always begin
        #100;
        if ($time >= 1000) $finish ;
    end

 
endmodule

Die Simulationsergebnisse sind wie folgt.

Aus der Abbildung ist ersichtlich, dass das Ausgangssignal mit den Zuständen des Auswahl- und Eingangssignals übereinstimmt.

Im Beispiel führt jede if-Bedingung nur eine Anweisung aus, daher werden die Schlüsselwörter begin und end nicht verwendet. In einer if-if-else-Form kann jedoch selbst dann, wenn nur eine Ausführungsanweisung vorhanden ist, die Nichtverwendung von begin und end zu Mehrdeutigkeiten führen.

Zum Beispiel ist im folgenden Code, obwohl die Formatierung es unterscheidet, unklar, welcher if-Bedingung das else entspricht.

Beispiel

if(en)
    if(sel == 2'b1)
        sout = p1s ;
    else
        sout = p0 ;

Natürlich folgen Compiler im Allgemeinen dem Prinzip der nächsten Übereinstimmung, sodass else dem nächstgelegenen if entspricht (dem zweiten if im Beispiel).

Aber offensichtlich ist dieser Schreibstil nicht standardkonform und unsicher.

Daher ist es eine gute Angewohnheit, die Schlüsselwörter begin und end in bedingten Anweisungen hinzuzufügen.

Wenn beispielsweise der obige Code leicht geändert wird, gibt es in der Schreibweise keine Mehrdeutigkeit mehr.

Beispiel

if(en) begin
    if(sel == 2'b1) begin
        sout = p1s ;
    end
    else begin
        sout = p0 ;
    end
end

Quellcode-Download

Herunterladen