Los UDP de lógica secuencial y los UDP de lógica combinacional difieren tanto en su forma de definición como en su comportamiento funcional. Las principales diferencias son las siguientes:

  • 1. El puerto de salida de un UDP de lógica secuencial debe declararse como tipo reg.
  • 2. Un UDP de lógica secuencial puede inicializarse con una sentencia initial.
  • 3. El formato de la tabla de estados también es ligeramente diferente:
    ...    :  <current_state>  :  <next_state>  ;
  • 4. Cada fila de la tabla de estados de un UDP de lógica secuencial consta de 3 partes: la parte de entrada, el estado actual y el estado de salida, separadas por dos puntos ':'.
  • 5. current_state es el valor actual del registro de salida, y next_state es el nuevo valor del registro de salida. next_state está determinado conjuntamente por las entradas y current_state.
  • 6. Los elementos de entrada de la tabla de estados pueden ser niveles o flancos de transición.

Los UDP que representan lógica secuencial se dividen principalmente en 2 tipos: UDP sensible al nivel y UDP sensible al flanco.

UDP sensible al nivel

La salida de un UDP sensible al nivel cambia de acuerdo con los cambios en el estado de nivel de las entradas.

La descripción funcional de un latch D con terminal de borrado es la siguiente:

  • Cuando el terminal de borrado es 1, la salida es siempre 0;
  • Cuando el terminal de borrado es 0 y el terminal de habilitación es 1, el latch es transparente y la salida es igual a la entrada;
  • Cuando el terminal de borrado es 0 y el terminal de habilitación es 0, el latch está en estado de retención y la salida permanece sin cambios.

Su tabla de verdad es (q representa el estado actual, q+ representa el siguiente estado):

En realidad, el proceso de escribir un UDP puede entenderse como el proceso de escribir una tabla de verdad en otro formato.

El UDP del latch D con terminal de borrado puede describirse como sigue:

primitive d_latch(q, clear, en, d);
   output       q ;
   reg          q ;
   input        d, en, clear ;

   initial
     q = 0 ;

   table
    //clear     en      d       :q      :q+ ;
      1         ?       ?       :?      :0 ;    //clear
      0         0       ?       :?      :- ;    //"-" means stable

      0         1       0       :?      :0 ;    //q = d
      0         1       1       :?      :1 ;
   endtable
endprimitive

Por supuesto, también se puede declarar su tipo al enumerar las señales de puerto y asignar un valor inicial.

primitive d_latch2(
   output reg   q = 0,
   input        clear, en, d);
   ......
endprimitive

UDP sensible al flanco

La salida de un UDP sensible al flanco cambia según los flancos de transición de las entradas y/o los cambios en el estado de nivel de las entradas.

A continuación se da directamente la 'tabla de verdad' de un flip-flop D con terminal de reset asíncrono (RST) que captura la señal en el flanco de bajada del reloj:

Se puede ver que en esta 'tabla de verdad' también se añade el concepto de flanco ascendente y descendente, para facilitar la escritura del código UDP.

La descripción del UDP de lógica secuencial de este flip-flop D es la siguiente:

primitive D_TRI(
            output reg  Q = 0,
            input       RST, CP, D);
   table
    //RST       CP      D       :Q      :Q+ ;
      //(1) Puesta a cero
      1         ?       ?       :?      :0 ;  //Puesta a cero cuando RST=1
      (??)      ?       ?       :?      :- ;  //Se ignoran los cambios de flanco de RST
      //(2) Captura en flanco de bajada del reloj
      0         (10)    0       :?      :0 ;  //Captura la señal en el flanco de bajada del reloj
      0         (10)    1       :?      :1 ;
      //possible negedge
      0         (1x)    ?       :?      :- ;  //Posible retención en el flanco de bajada del reloj
      0         (x0)    ?       :?      :- ;
      //(3) Retención en el flanco de subida del reloj
      0         (0?)    ?       :?      :- ;  //Retención en el flanco de subida del reloj
      //possible posedge
      0         (x1)    ?       :?      :- ;  //Posible retención en el flanco de subida del reloj
      //(4) Cuando no hay flanco de reloj, incluso si los datos cambian, la salida se mantiene
      0         ?       (??)    :?      :- ;  
   endtable
endprimitive // D_TRI

Para realizar una simulación simple de este flip-flop, el testbench se describe a continuación.

Ejemplo

`timescale 1ns/1ps
module test ;
   reg  D, CP = 0 ;
   reg  RST ;
   wire Q ;
   always #5 CP = ~CP ;
   //data driver
   initial begin
      D = 0 ;
      #12 D = 1 ;
      #10 D = 0 ;
      #14  D = 1 ;
      #3  D = 0 ;
      #18  D = 0 ;
   end
   //reset driver
   initial begin
      RST = 0 ;
      #3        RST = 1 ;
      #2        RST = 0 ;
      #22       RST = 1 ;
      #1        RST = 0 ;
   end
   D_TRI u_d_trigger(Q, RST, CP, D);
   initial begin
      forever begin
         #100;
         //$display("---gyc---%d", $time);
         if ($time >= 1000) begin
            $finish ;
         end
      end
   end
endmodule // test

El resultado de la simulación es el siguiente.

Como se muestra en la figura, en el instante cap1, el terminal Q se pone a cero mediante reset; en el instante cap2, que es el flanco de bajada del reloj, la salida captura el valor 1 de la entrada D; en el instante cap3, el terminal Q vuelve a ponerse a cero. Coincide con el diseño.

Cabe señalar que:

En cada fila de la tabla de estados, entre las múltiples partes de entrada, solo puede haber como máximo un flanco de transición. Por ejemplo, la expresión de la tabla de estados siguiente es incorrecta.

   table
      ......
      (10)     (10)    1       :?      :1 ;
   endtable

Las entradas de la tabla de estados sensibles al nivel tienen mayor prioridad que las entradas de la tabla de estados sensibles al flanco. Si ambas aparecen en el mismo instante, el estado de salida lo determina la tabla de estados de activación por nivel.

Por ejemplo, en el flip-flop D anterior, RST puede considerarse como activación por nivel y CP como activación por flanco. Cuando el flanco de subida de RST y el flanco de bajada de CP llegan al mismo tiempo, la salida se pone a 0, como se muestra en el instante cap de la figura. Por supuesto, en la temporización real se debe evitar que los flancos de reloj y de reset coincidan.

En un UDP sensible al flanco, se debe especificar el cambio de la señal de salida ante los flancos de cada señal de entrada; de lo contrario, en el flanco de transición de esa señal la salida podría convertirse en X.

Por ejemplo, si falta la especificación de los flancos de RST:

    //(??)    ?       ?       :?      :- ; //忽略 RST 边沿变化

Entonces, en el flanco de bajada de RST, la salida se convertirá en x.

Otro ejemplo: si falta la especificación cuando el reloj está estable y los datos en D cambian:

    //(4) 非时钟沿变化时,即便数据有跳变,输出仍然保持
    //0         ?       (??)    :?      :- ;

Entonces, en el flanco del cambio de datos en D, la salida también se convertirá en x.


Abreviaturas de los símbolos de la tabla de estados UDP

Los símbolos abreviados para niveles y flancos de transición en la tabla de estados UDP y sus descripciones se muestran en la siguiente tabla.

AbreviaturaSignificadoDescripción
?0, 1, xSolo se puede usar para entradas
b1, 1Solo se puede usar para entradas
-Mantiene el valor original sin cambiosSolo se puede usar para salidas
(ab)La señal cambia de a a bSe utiliza para indicar flancos en las entradas
r(01)Flanco de subida de la señal
f(10)Flanco de bajada de la señal
p(01), (0x) o (x1)Puede ser el flanco de subida de la señal
n(10), (1x) o (x0)Puede ser el flanco de bajada de la señal
*(??)Cambio de cualquier flanco de la señal

Guía de diseño de UDP

A la hora de elegir entre usar module o primitive en el diseño digital, se deben considerar factores como los requisitos de diseño y la complejidad. A continuación se ofrecen algunas recomendaciones orientativas.

  • Los UDP solo pueden realizar modelado funcional; no pueden modelar la temporización del circuito ni el proceso de fabricación (por ejemplo, CMOS, TTL, etc.). El propósito principal de usar UDP es modelar diseños digitales de forma concisa, similar a una tabla de verdad, mientras que un module puede incluir la temporización del circuito y especificar el proceso de fabricación.
  • Los UDP solo pueden realizar diseños digitales con un puerto de salida. Cuando hay más de un puerto de salida, solo se puede usar module.
  • Los UDP se implementan mediante tablas de búsqueda en memoria. Cuando hay muchos puertos de entrada, las combinaciones de puertos de entrada crecen exponencialmente. El número de puertos de entrada de un UDP también está limitado por el simulador. Por lo tanto, no es recomendable usar UDP cuando hay demasiados puertos de entrada.
  • Después de elegir usar UDP, asegúrese de describir la tabla de estados UDP lo más completa posible con las abreviaturas. Si se omiten combinaciones de entrada, la salida puede presentar el estado X, lo que provocará errores de diseño.

Descargar el código fuente de este capítulo

Download