Встроенные функции AWK в основном включают следующие типы:

Арифметические функции

Имя функции Описание Пример
atan2( y, x ) Возвращает арктангенс y/x.
$ awk 'BEGIN {
  PI = 3.14159265
  x = -10
  y = 10
  result = atan2 (y,x) * 180 / PI;

  printf "The arc tangent for (x=%f, y=%f) is %f degrees\n", x, y, result
}'

Результат вывода:

The arc tangent for (x=-10.000000, y=10.000000) is 135.000000 degrees
cos( x ) Возвращает косинус x; x измеряется в радианах.
$ awk 'BEGIN {
  PI = 3.14159265
  param = 60
  result = cos(param * PI / 180.0);

  printf "The cosine of %f degrees is %f.\n", param, result
}'

Результат вывода:

The cosine of 60.000000 degrees is 0.500000.
sin( x ) Возвращает синус x; x задаётся в радианах.
$ awk 'BEGIN {
  PI = 3.14159265
  param = 30.0
  result = sin(param * PI /180)

  printf "The sine of %f degrees is %f.\n", param, result
}'

Результат вывода:

The sine of 30.000000 degrees is 0.500000.
exp( x ) Возвращает показательную функцию от x.
$ awk 'BEGIN {
  param = 5
  result = exp(param);

  printf "The exponential value of %f is %f.\n", param, result
}'

Результат вывода:

The exponential value of 5.000000 is 148.413159.
log( x ) Возвращает натуральный логарифм x.
$ awk 'BEGIN {
  param = 5.5
  result = log (param)

  printf "log(%f) = %f\n", param, result
}'

Результат вывода:

log(5.500000) = 1.704748
sqrt( x ) Возвращает квадратный корень из x.
$ awk 'BEGIN {
  param = 1024.0
  result = sqrt(param)

  printf "sqrt(%f) = %f\n", param, result
}'

Результат вывода:

sqrt(1024.000000) = 32.000000
int( x ) Возвращает значение x, усечённое до целого числа.
$ awk 'BEGIN {
  param = 5.12345
  result = int(param)

  print "Truncated value =", result
}'

Результат вывода:

Truncated value = 5
rand( ) Возвращает произвольное число n, где 0 <= n < 1.
$ awk 'BEGIN {
  print "Random num1 =" , rand()
  print "Random num2 =" , rand()
  print "Random num3 =" , rand()
}'

Результат вывода:

Random num1 = 0.237788
Random num2 = 0.291066
Random num3 = 0.845814
srand( [Expr] ) Устанавливает начальное значение (seed) функции rand равным значению параметра Expr; если параметр Expr опущен, используется текущее время суток. Возвращает предыдущее значение начального числа.
$ awk 'BEGIN {
  param = 10

  printf "srand() = %d\n", srand()
  printf "srand(%d) = %d\n", param, srand(param)
}'

Результат вывода:

srand() = 1
srand(10) = 1417959587

Строковые функции

Функция Описание Пример
gsub( Ere, Repl, [ In ] ) gsub — это сокращение от global substitution. За исключением того, что заменяются все конкретные значения регулярного выражения, она выполняет точно то же самое, что и функция sub.
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    gsub("World", "Jerry", str)

    print "String after replacement = " str
}'

Результат вывода:

String before replacement = Hello, World
String after replacement = Hello, Jerry
sub(regex,sub,string) Функция sub выполняет одну замену подстроки. Она заменяет первое вхождение подстроки, соответствующее regex. Третий параметр необязателен, по умолчанию равен $0.
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    sub("World", "Jerry", str)

    print "String after replacement = " str
}'

Результат вывода:

String before replacement = Hello, World
String after replacement = Hello, Jerry
substr(str, start, l) Функция substr возвращает подстроку строки str, начиная с start-го символа, длиной l. Если значение l не указано, возвращается суффиксная подстрока str, начиная с start-го символа.
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

Результат вывода:

Substring = Hello
index( String1, String2 ) В строке, заданной параметром String1 (там, где встречается параметр, заданный String2), возвращает позицию, отсчитываемую с 1. Если параметр String2 не встречается в параметре String1, возвращает 0 (ноль).
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = index(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

Результат вывода:

Substring "Two" found at 5 location.
length [(String)] Возвращает длину (в символах) строки, заданной параметром String. Если параметр String не указан, возвращает длину всей записи (переменная записи $0).
$ awk 'BEGIN {
    str = "Hello, World !!!"

    print "Length = ", length(str)
}'

Результат вывода:

Substring "Two" found at 5 location.
blength [(String)] Возвращает длину (в байтах) строки, заданной параметром String. Если параметр String не указан, возвращает длину всей записи (переменной записи $0).  
substr( String, M, [ N ] ) Возвращает подстроку, содержащую число символов, заданное параметром N. Подстрока берётся из строки, заданной параметром String; её символы начинаются с позиции, заданной параметром M. Параметр M задаётся так, что первый символ в параметре String считается номером 1. Если параметр N не указан, длина подстроки будет равна длине от позиции, заданной параметром M, до конца параметра String.
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

Результат вывода:

Substring = Hello
match( String, Ere ) В строке, заданной параметром String (там, где встречается расширенное регулярное выражение, заданное параметром Ere), возвращает позицию (в символах), нумеруемую с 1, или возвращает 0 (ноль), если параметр Ere не встречается. Специальной переменной RSTART присваивается возвращаемое значение. Специальной переменной RLENGTH присваивается длина совпавшей строки или -1 (минус один), если совпадение не найдено.
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = match(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

Результат вывода:

Substring "Two" found at 5 location.
split( String, A, [Ere] ) Разделяет аргумент, заданный параметром String, на элементы массива A
$ awk 'BEGIN {
    str = "One,Two,Three,Four"

    split(str, arr, ",")

    print "Array contains following values"

    for (i in arr) {
        print arr[i]
    }
}'

Результат вывода:

Array contains following values
One
Two
Three
Four
tolower( String ) Возвращает строку, заданную параметром String, в которой каждый символ верхнего регистра заменён на символ нижнего регистра. Соответствие между верхним и нижним регистром определяется категорией LC_CTYPE текущей локали.
$ awk 'BEGIN {
    str = "HELLO, WORLD !!!"

    print "Lowercase string = " tolower(str)
}'

Результат вывода:

Lowercase string = hello, world !!!
toupper( String ) Возвращает строку, заданную параметром String, в которой каждый символ нижнего регистра заменён на символ верхнего регистра. Соответствие между верхним и нижним регистром определяется категорией LC_CTYPE текущей локали.
$ awk 'BEGIN {
    str = "hello, world !!!"

    print "Uppercase string = " toupper(str)
}'

Результат вывода:

Uppercase string = HELLO, WORLD !!!
sprintf(Format, Expr, Expr, . . . ) Форматирует выражение, заданное параметром Expr, в соответствии со строкой формата подпрограммы printf, заданной параметром Format, и возвращает полученную строку.
$ awk 'BEGIN {
    str = sprintf("%s", "Hello, World !!!")

    print str
}'

Результат вывода:

Hello, World !!!
strtonum(str) strtonum преобразует строку str в числовое значение. Если строка начинается с 0, она рассматривается как восьмеричное число; если строка начинается с 0x или 0X, она рассматривается как шестнадцатеричное число; в противном случае она рассматривается как число с плавающей запятой.
$ awk 'BEGIN {
    print "十进制数 = " strtonum("123")
    print "八进制数 = " strtonum("0123")
    print "十六进制数 = " strtonum("0x123")
}'

Результат вывода:

十进制数 = 123
八进制数 = 83
十六进制数 = 291

Примечание:EreЭта часть может быть регулярным выражением.

1. Использование gsub и sub

$ awk 'BEGIN{info="this is a test2012test!";gsub(/[0-9]+/,"||",info);print info}'
this is a test||test!

2. Поиск строки (с использованием index)

Используется тернарный оператор:expression ? action1 : action2

$ awk 'BEGIN{info="this is a test2012test!";print index(info,"11111")?"ok":"no found";}'
no found
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"is")?"ok":"no found";}'
ok
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"test")?"ok":"no found";}'
ok

3. Поиск совпадений регулярного выражения (с использованием match)

$ awk 'BEGIN{info="this is a test2012test!";print match(info,/[0-9]+/)?"ok":"no found";}'
ok

4. Извлечение подстроки (с использованием substr)

Начиная с 4-го символа, извлечь строку длиной 10.

$ awk 'BEGIN{info="this is a test2012test!";print substr(info,4,10);}'
s is a tes

5. Разделение строки (с использованием split)

$ awk 'BEGIN{info="this is a test";split(info,tA," ");print length(tA);for(k in tA){print k,tA[k];}}'
4
2 is
3 a
4 test
1 this

Разделите info; используйте пробелы, чтобы разбить строку info на динамический массив tA. Обратите внимание, что цикл awk for...in является неупорядоченным циклом. Он не идёт от индекса массива 1...n, поэтому при его использовании требуется особая осторожность.

6. Форматирование вывода строк (с использованием sprintf)

Строка форматирования состоит из двух частей: одна часть — обычные символы, которые выводятся как есть; другая часть — спецификаторы формата, начинающиеся с%, за которыми следуют один или несколько символов-спецификаторов, используемых для определения формата выводимого содержимого. Следует обратить особое внимание, что использованиеprintfпо умолчанию не добавляет новую строку, тогда какprintэта функция по умолчанию добавляет после каждой строки\nсимвол новой строки.

Спецификатор формата Описание
%d Десятичное целое число со знаком
%u Десятичное беззнаковое целое число
%f Число с плавающей запятой
%s String
%c Одиночный символ
%p Значение указателя
%e Число с плавающей запятой в экспоненциальной форме
%x %X беззнаковое целое число в шестнадцатеричном представлении
%o беззнаковое целое число в восьмеричном представлении
%g Автоматически выбрать подходящее представление
$ awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2345; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.2,7C,174
$  awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2645; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.3,7C,174

Примечание:Глядя на выходное значение n3 выше, вы обнаружите, что довольно интеллектуальная особенность при обработке с помощью printf заключается в том, что оно может округлять до указанного количества десятичных знаков.

Функции времени

Имя функции Описание Пример
mktime( YYYY MM DD HH MM SS[ DST]) Сгенерировать формат времени
$ awk 'BEGIN {
    print "Number of seconds since the Epoch = " mktime("2014 12 14 30 20 10")
}'

Результат вывода:

Number of seconds since the Epoch = 1418604610
strftime([format [, timestamp]]) Форматировать вывод времени, преобразовать метку времени в строку времени
Для конкретных форматов см. таблицу ниже.
$ awk 'BEGIN {
    print strftime("Time = %m/%d/%Y %H:%M:%S", systime())
}'

Результат вывода:

Time = 12/14/2014 22:08:42
systime() Получить метку времени, возвращающую общее количество секунд с 1 января 1970 года до текущего времени (не считая високосные годы)
awk 'BEGIN{now=systime();print now}'

Результат вывода:

1343210982

Спецификаторы формата даты и времени strftime:

Нет. Описание
%a Сокращённое название дня недели (Пн-Вс).
%A Полное название дня недели (понедельник-воскресенье).
%b Сокращённое название месяца (янв.).
%B Полное название месяца (январь).
%c Локальные дата и время.
%C Часть года, соответствующая веку, значение которой равно году, делённому на 100.
%d Десятичная дата (01-31)
%D Эквивалентно %m/%d/%y.
%e Дата, дополненная пробелом, если она состоит только из одной цифры.
%F Эквивалентно %Y-%m-%d, что также является стандартным форматом даты ISO 8601.
%g Год недели стандарта ISO8610 по модулю 100 (00-99). Например, 1 января 1993 года относится к 53-й неделе 1992 года. Поэтому, хотя это 1-й день 1993 года, его год по неделям стандарта ISO8601 — 1992. Аналогично, хотя 31 декабря 1973 года относится к 1973 году, оно относится к первой неделе 1994 года. Следовательно, год по неделям стандарта ISO8610 для 31 декабря 1973 года — 1974, а не 1973.
%G Полный год, соответствующий году нумерации недель ISO.
%h Эквивалентно %b.
%H Час в 24-часовом формате в виде десятичного числа (00-23)
%I Час в 12-часовом формате в виде десятичного числа (00-12)
%j День года (001-366)
%m Месяц (01-12)
%M Минута (00-59)
%n Символ новой строки (ASCII LF)
%p 12-часовой формат (AM/PM)
%r Время в 12-часовом формате (эквивалентно %I:%M:%S %p).
%R Эквивалентно %H:%M.
%S Значение секунд времени (00-60)
%t Символ табуляции (tab)
%T Эквивалентно %H:%M:%S.
%u День недели в виде числа (1-7), 1 — понедельник.
%U Номер недели года (воскресенье как первый день недели), 00-53
%V Номер недели года (понедельник как первый день недели), 01-53.
%w День недели в виде числа (0-6), 0 — воскресенье.
%W Номер недели года в виде десятичного числа (понедельник как первый день недели), 00-53.
%x Локальное представление даты
%X Локальное представление времени
%y Год по модулю 100.
%Y Полный год в виде десятичного числа.
%z Часовой пояс в формате +HHMM (например, формат, требуемый для заголовков времени RFC 822 или RFC 1036)
%Z Название или сокращение часового пояса; ничего не выводится, если часовой пояс не удаётся определить.

Поразрядные функции

Имя функции Описание Пример
и Побитовая операция AND.
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d AND %d) = %d\n", num1, num2, and(num1, num2)
}'

Вывод:

(10 AND 6) = 2
compl Побитовое дополнение.
$ awk 'BEGIN {
    num1 = 10

    printf "compl(%d) = %d\n", num1, compl(num1)
}'

Вывод:

compl(10) = 9007199254740981
lshift Операция сдвига влево
$ awk 'BEGIN {
    num1 = 10

    printf "lshift(%d) by 1 = %d\n", num1, lshift(num1, 1)
}'

Вывод:

lshift(10) by 1 = 20
rshift Операция сдвига вправо
$ awk 'BEGIN {
    num1 = 10

    printf "rshift(%d) by 1 = %d\n", num1, rshift(num1, 1)
}'

Вывод:

rshift(10) by 1 = 5
или Побитовая операция OR
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d OR %d) = %d\n", num1, num2, or(num1, num2)
}'

Вывод:

(10 OR 6) = 14
xor Побитовая операция XOR
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d XOR %d) = %d\n", num1, num2, xor(num1, num2)
}'

Вывод:

(10 bitwise xor 6) = 12

Другие функции

Имя функции Описание Пример
close(expr) Закрыть файл или канал
$ awk 'BEGIN {
    cmd = "tr [a-z] [A-Z]"
    print "hello, world !!!" |& cmd
    close(cmd, "to")
    cmd |& getline out
    print out;
    close(cmd);
}'

Вывод:

HELLO, WORLD !!!
  • Первый оператор cmd = "tr [a-z] [A-Z]" устанавливает двусторонний канал связи в AWK.
  • Второй оператор print передаёт вход команде tr. &| указывает на двустороннюю связь.
  • Третий оператор close(cmd, "to") закрывает процесс to после завершения выполнения.
  • Четвёртый оператор cmd |& getline out использует функцию getline, чтобы сохранить вывод в переменную out.
  • Следующий оператор вывода печатает содержимое выходных данных, и наконец функция close закрывает cmd.
удаление Используется для удаления элемента из массива
$ awk 'BEGIN {
    arr[0] = "One"
    arr[1] = "Two"
    arr[2] = "Three"
    arr[3] = "Four"

    print "Array elements before delete operation:"
    for (i in arr) {
        print arr[i]
    }

    delete arr[0]
    delete arr[1]

    print "Array elements after delete operation:"
    for (i in arr) {
        print arr[i]
    }
}'

Вывод:

Array elements before delete operation:
One
Two
Three
Four

Array elements after delete operation:
Three
Four
exit Завершает выполнение скрипта; может принимать необязательный аргумент expr для передачи статуса возврата AWK.
$ awk 'BEGIN {
    print "Hello, World !!!"

    exit 10

    print "AWK never executes this statement."
}'

Вывод:

Hello, World !!!
flush Сбрасывает буфер открытого файла или канала  
getline Считывает следующую строку

Используйте getline, чтобы прочитать строку из файла marks.txt и вывести её:

$ awk '{getline; print $0}' marks.txt 

AWK считывает строку из файла marks.txt и сохраняет её в переменную 0. В следующем операторе мы используем getline, чтобы прочитать следующую строку. Поэтому AWK считывает вторую строку и сохраняет её в переменную 0. Наконец, AWK использует print для вывода содержимого второй строки. Этот процесс продолжается до конца файла.

Далее Остановить обработку текущей записи и перейти к обработке следующей записи.

Когда шаблон успешно совпадает, программа не выполняет никаких операций:

$ awk '{if ($0 ~/Shyam/) next; print $0}' marks.txt
nextfile Остановить обработку текущего файла и начать обработку с первой записи следующего файла.

Сначала создайте два файла. Содержимое file1.txt следующее:

file1:str1
file1:str2
file1:str3
file1:str4

Содержимое file2.txt следующее:

file2:str1
file2:str2
file2:str3
file2:str4

Теперь протестируем функцию nextfile.

$ awk '{ if ($0 ~ /file1:str2/) nextfile; print $0 }' file1.txt file2.txt

Вывод:

file1:str1
file2:str1
file2:str2
file2:str3
file2:str4
return Вернуть значение из пользовательской функции. Обратите внимание, что если возвращаемое значение не указано, возвращаемое значение не определено.

Создайте файл functions.awk со следующим содержимым:

function addition(num1, num2)
{
    result = num1 + num2

    return result
}

BEGIN {
    res = addition(10, 20)
    print "10 + 20 = " res
}

Выполните файл:

$ awk -f functions.awk 
10 + 20 = 30
system Выполнить определённую команду и вернуть её статус выхода. Возвращаемое значение 0 означает, что команда выполнилась успешно; ненулевое значение означает, что команда завершилась с ошибкой.
$ awk 'BEGIN { ret = system("date"); print "Return value = " ret }'

Вывод:

Sun Dec 21 23:16:07 IST 2014
Return value = 0