Les fonctions intégrées d’AWK comprennent principalement les types suivants :

Fonctions arithmétiques

Nom de la fonction Description Exemple
atan2( y, x ) Renvoie l’arctangente de y/x.
$ awk 'BEGIN {
  PI = 3.14159265
  x = -10
  y = 10
  result = atan2 (y,x) * 180 / PI;

  printf "The arc tangent for (x=%f, y=%f) is %f degrees\n", x, y, result
}'

Le résultat de sortie est:

The arc tangent for (x=-10.000000, y=10.000000) is 135.000000 degrees
cos( x ) Renvoie le cosinus de x ; x est en radians.
$ awk 'BEGIN {
  PI = 3.14159265
  param = 60
  result = cos(param * PI / 180.0);

  printf "The cosine of %f degrees is %f.\n", param, result
}'

Le résultat de sortie est:

The cosine of 60.000000 degrees is 0.500000.
sin( x ) Renvoie le sinus de x ; x est en radians.
$ awk 'BEGIN {
  PI = 3.14159265
  param = 30.0
  result = sin(param * PI /180)

  printf "The sine of %f degrees is %f.\n", param, result
}'

Le résultat de sortie est:

The sine of 30.000000 degrees is 0.500000.
exp( x ) Renvoie la fonction puissance de x.
$ awk 'BEGIN {
  param = 5
  result = exp(param);

  printf "The exponential value of %f is %f.\n", param, result
}'

Le résultat de sortie est:

The exponential value of 5.000000 is 148.413159.
log( x ) Renvoie le logarithme népérien de x.
$ awk 'BEGIN {
  param = 5.5
  result = log (param)

  printf "log(%f) = %f\n", param, result
}'

Le résultat de sortie est:

log(5.500000) = 1.704748
sqrt( x ) Renvoie la racine carrée de x.
$ awk 'BEGIN {
  param = 1024.0
  result = sqrt(param)

  printf "sqrt(%f) = %f\n", param, result
}'

Le résultat de sortie est:

sqrt(1024.000000) = 32.000000
int( x ) Renvoie la valeur de x tronquée à un entier.
$ awk 'BEGIN {
  param = 5.12345
  result = int(param)

  print "Truncated value =", result
}'

Le résultat de sortie est:

Truncated value = 5
rand( ) Renvoie un nombre arbitraire n, où 0 <= n < 1.
$ awk 'BEGIN {
  print "Random num1 =" , rand()
  print "Random num2 =" , rand()
  print "Random num3 =" , rand()
}'

Le résultat de sortie est:

Random num1 = 0.237788
Random num2 = 0.291066
Random num3 = 0.845814
srand( [Expr] ) Définit la valeur de graine de la fonction rand sur la valeur du paramètre Expr, ou, si le paramètre Expr est omis, utilise l'heure du jour. Renvoie la valeur de graine précédente.
$ awk 'BEGIN {
  param = 10

  printf "srand() = %d\n", srand()
  printf "srand(%d) = %d\n", param, srand(param)
}'

Le résultat de sortie est:

srand() = 1
srand(10) = 1417959587

Fonctions de chaînes

Fonction Description Exemple
gsub( Ere, Repl, [ In ] ) gsub est l'abréviation de global substitution. Excepté que toutes les valeurs spécifiques de l'expression régulière sont remplacées, il se comporte exactement comme la fonction sub.
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    gsub("World", "Jerry", str)

    print "String after replacement = " str
}'

Le résultat de sortie est:

String before replacement = Hello, World
String after replacement = Hello, Jerry
sub(regex,sub,string) La fonction sub effectue un remplacement de sous-chaîne. Elle remplace la première occurrence d'une sous-chaîne par regex. Le troisième paramètre est facultatif, sa valeur par défaut étant $0.
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    sub("World", "Jerry", str)

    print "String after replacement = " str
}'

Le résultat de sortie est:

String before replacement = Hello, World
String after replacement = Hello, Jerry
substr(str, start, l) La fonction substr renvoie une sous-chaîne de la chaîne str à partir du caractère start avec une longueur l. Si la valeur de l n'est pas spécifiée, elle renvoie la sous-chaîne suffixe de str à partir du caractère start.
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

Le résultat de sortie est:

Substring = Hello
index( String1, String2 ) Dans la chaîne spécifiée par le paramètre String1 (où apparaît le paramètre spécifié par String2), renvoie la position, numérotée à partir de 1. Si le paramètre String2 n'apparaît pas dans le paramètre String1, renvoie 0 (zéro).
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = index(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

Le résultat de sortie est:

Substring "Two" found at 5 location.
length [(String)] Renvoie la longueur (en caractères) de la chaîne spécifiée par le paramètre String. Si le paramètre String n'est pas donné, renvoie la longueur de l'enregistrement entier (variable d'enregistrement $0).
$ awk 'BEGIN {
    str = "Hello, World !!!"

    print "Length = ", length(str)
}'

Le résultat de sortie est:

Substring "Two" found at 5 location.
blength [(String)] Renvoie la longueur (en octets) de la chaîne spécifiée par le paramètre String. Si le paramètre String n'est pas fourni, renvoie la longueur de l'enregistrement entier (variable d'enregistrement $0).  
substr( String, M, [ N ] ) Renvoie une sous-chaîne ayant le nombre de caractères spécifié par le paramètre N. La sous-chaîne est extraite de la chaîne spécifiée par le paramètre String, ses caractères commençant à la position spécifiée par le paramètre M. Le paramètre M est spécifié avec le premier caractère du paramètre String comme numéro 1. Si le paramètre N n'est pas spécifié, la longueur de la sous-chaîne sera la longueur allant de la position spécifiée par le paramètre M jusqu'à la fin du paramètre String.
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

Le résultat de sortie est:

Substring = Hello
match( String, Ere ) Dans la chaîne spécifiée par le paramètre String (où apparaît l'expression régulière étendue spécifiée par le paramètre Ere), renvoie la position (sous forme de caractère), numérotée à partir de 1, ou renvoie 0 (zéro) si le paramètre Ere n'apparaît pas. La variable spéciale RSTART est définie sur la valeur de retour. La variable spéciale RLENGTH est définie sur la longueur de la chaîne correspondante, ou sur -1 (moins un) si aucune correspondance n'est trouvée.
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = match(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

Le résultat de sortie est:

Substring "Two" found at 5 location.
split( String, A, [Ere] ) Divise l'argument spécifié par le paramètre String en éléments de tableau A
$ awk 'BEGIN {
    str = "One,Two,Three,Four"

    split(str, arr, ",")

    print "Array contains following values"

    for (i in arr) {
        print arr[i]
    }
}'

Le résultat de sortie est:

Array contains following values
One
Two
Three
Four
tolower( String ) Renvoie la chaîne spécifiée par le paramètre String, avec chaque caractère majuscule changé en minuscule. La correspondance entre majuscules et minuscules est définie par la catégorie LC_CTYPE de la locale actuelle.
$ awk 'BEGIN {
    str = "HELLO, WORLD !!!"

    print "Lowercase string = " tolower(str)
}'

Le résultat de sortie est:

Lowercase string = hello, world !!!
toupper( String ) Renvoie la chaîne spécifiée par le paramètre String, avec chaque caractère minuscule changé en majuscule. La correspondance entre majuscules et minuscules est définie par la catégorie LC_CTYPE de la locale actuelle.
$ awk 'BEGIN {
    str = "hello, world !!!"

    print "Uppercase string = " toupper(str)
}'

Le résultat de sortie est:

Uppercase string = HELLO, WORLD !!!
sprintf(Format, Expr, Expr, . . . ) Formate l'expression spécifiée par le paramètre Expr selon la chaîne de format de la sous-routine printf spécifiée par le paramètre Format et renvoie la chaîne résultante.
$ awk 'BEGIN {
    str = sprintf("%s", "Hello, World !!!")

    print str
}'

Le résultat de sortie est:

Hello, World !!!
strtonum(str) strtonum convertit la chaîne str en une valeur numérique. Si la chaîne commence par 0, elle est traitée comme un nombre octal ; si la chaîne commence par 0x ou 0X, elle est traitée comme un nombre hexadécimal ; sinon, elle est traitée comme un nombre à virgule flottante.
$ awk 'BEGIN {
    print "十进制数 = " strtonum("123")
    print "八进制数 = " strtonum("0123")
    print "十六进制数 = " strtonum("0x123")
}'

Le résultat de sortie est:

十进制数 = 123
八进制数 = 83
十六进制数 = 291

Remarque :EreLa partie peut être une expression régulière.

1. Utilisation de gsub et sub

$ awk 'BEGIN{info="this is a test2012test!";gsub(/[0-9]+/,"||",info);print info}'
this is a test||test!

2. Recherche d'une chaîne (en utilisant index)

Un opérateur ternaire est utilisé :expression ? action1 : action2

$ awk 'BEGIN{info="this is a test2012test!";print index(info,"11111")?"ok":"no found";}'
no found
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"is")?"ok":"no found";}'
ok
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"test")?"ok":"no found";}'
ok

3. Recherche par correspondance d'expression régulière (en utilisant match)

$ awk 'BEGIN{info="this is a test2012test!";print match(info,/[0-9]+/)?"ok":"no found";}'
ok

4. Extraction d'une sous-chaîne (en utilisant substr)

À partir du 4e caractère, extrayez une chaîne de longueur 10.

$ awk 'BEGIN{info="this is a test2012test!";print substr(info,4,10);}'
s is a tes

5. Découpage de chaîne (en utilisant split)

$ awk 'BEGIN{info="this is a test";split(info,tA," ");print length(tA);for(k in tA){print k,tA[k];}}'
4
2 is
3 a
4 test
1 this

Découpez info ; utilisez des espaces pour diviser la chaîne info en un tableau dynamique tA. Notez que la boucle for...in d'awk est une boucle non ordonnée. Elle ne parcourt pas les indices du tableau de 1...n, donc une attention particulière est nécessaire lors de son utilisation.

6. Formatage de la sortie de chaîne (avec sprintf)

La chaîne de format se compose de deux parties : une partie correspond à des caractères normaux, qui seront affichés tels quels ; l'autre partie correspond à des spécificateurs de format, commençant par%suivis d'un ou plusieurs caractères de spécification, utilisés pour déterminer le format du contenu de sortie. Il faut particulièrement noter que l'utilisation deprintfn’ajoute pas de saut de ligne par défaut, tandis que la fonctionprintajoute par défaut après chaque ligne\nun caractère de saut de ligne.

Spécificateur de format Description
%d Entier signé décimal
%u Entier non signé décimal
%f Nombre à virgule flottante
%s String
%c Caractère unique
%p La valeur d’un pointeur
%e Nombre à virgule flottante en notation exponentielle
%x %X entier non signé en représentation hexadécimale
%o entier non signé en représentation octale
%g Choisir automatiquement une représentation appropriée
$ awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2345; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.2,7C,174
$  awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2645; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.3,7C,174

Remarque :En regardant la valeur de sortie n3 ci-dessus, vous constaterez qu’une fonctionnalité relativement intelligente lors du traitement avec printf est qu’il peut arrondir aux décimales spécifiées.

Fonctions temporelles

Nom de la fonction Description Exemple
mktime( YYYY MM DD HH MM SS[ DST]) Générer le format de l’heure
$ awk 'BEGIN {
    print "Number of seconds since the Epoch = " mktime("2014 12 14 30 20 10")
}'

Le résultat de sortie est:

Number of seconds since the Epoch = 1418604610
strftime([format [, timestamp]]) Formate la sortie temporelle, convertit un horodatage en chaîne de temps
Pour des formats spécifiques, voir le tableau ci-dessous.
$ awk 'BEGIN {
    print strftime("Time = %m/%d/%Y %H:%M:%S", systime())
}'

Le résultat de sortie est:

Time = 12/14/2014 22:08:42
systime() Récupère l'horodatage, en renvoyant le nombre total de secondes depuis le 1er janvier 1970 jusqu'à l'heure actuelle (sans compter les années bissextiles)
awk 'BEGIN{now=systime();print now}'

Le résultat de sortie est:

1343210982

Spécificateurs de format de date et d'heure de strftime :

Non. Description
%a Abréviation du jour de la semaine (lun-dim).
%A Nom complet du jour de la semaine (lundi-dimanche).
%b Abréviation du mois (janv.).
%B Nom complet du mois (janvier).
%c Date et heure locales.
%C La partie siècle de l'année, dont la valeur est l'année divisée par 100.
%d Date décimale (01-31)
%D Équivalent à %m/%d/%y.
%e Date, complétée par un espace si elle ne comporte qu'un seul chiffre.
%F Équivalent à %Y-%m-%d, qui est aussi le format de date standard ISO 8601.
%g L'année de la semaine standard ISO8610 modulo 100 (00-99). Par exemple, le 1er janvier 1993 appartient à la 53e semaine de 1992. Ainsi, bien qu'il s'agisse du 1er jour de 1993, son année basée sur la semaine standard ISO8601 est 1992. De même, bien que le 31 décembre 1973 appartienne à 1973, il appartient à la première semaine de 1994. Par conséquent, l'année basée sur la semaine standard ISO8610 pour le 31 décembre 1973 est 1974 plutôt que 1973.
%G Année complète correspondant à l'année de numérotation des semaines ISO.
%h Équivalent à %b.
%H Heure au format 24 heures sous forme de nombre décimal (00-23)
%I Heure au format 12 heures sous forme de nombre décimal (00-12)
%j Jour de l'année (001-366)
%m Mois (01-12)
%M Minute (00-59)
%n Caractère de saut de ligne (ASCII LF)
%p Format 12 heures (AM/PM)
%r Heure au format 12 heures (équivalent à %I:%M:%S %p).
%R Équivalent à %H:%M.
%S Valeur des secondes de l'heure (00-60)
%t Caractère de tabulation (tab)
%T Équivalent à %H:%M:%S.
%u Jour de la semaine sous forme de nombre (1-7), 1 correspond à lundi.
%U Numéro de semaine de l'année (dimanche comme premier jour de la semaine), 00-53
%V Numéro de semaine de l'année (lundi comme premier jour de la semaine), 01-53.
%w Jour de la semaine sous forme de nombre (0-6), 0 correspond à dimanche.
%W Numéro de semaine de l'année sous forme de nombre décimal (lundi comme premier jour de la semaine), 00-53.
%x Représentation locale de la date
%X Représentation locale de l'heure
%y Année modulo 100.
%Y Année complète sous forme de nombre décimal.
%z Fuseau horaire au format +HHMM (par exemple, le format requis pour les en-têtes d'heure RFC 822 ou RFC 1036)
%Z Nom ou abréviation du fuseau horaire, aucune sortie si le fuseau horaire ne peut pas être déterminé.

Fonctions bit à bit

Nom de la fonction Description Exemple
et Opération AND bit à bit.
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d AND %d) = %d\n", num1, num2, and(num1, num2)
}'

La sortie est :

(10 AND 6) = 2
compl Complément bit à bit.
$ awk 'BEGIN {
    num1 = 10

    printf "compl(%d) = %d\n", num1, compl(num1)
}'

La sortie est :

compl(10) = 9007199254740981
lshift Opération de décalage à gauche
$ awk 'BEGIN {
    num1 = 10

    printf "lshift(%d) by 1 = %d\n", num1, lshift(num1, 1)
}'

La sortie est :

lshift(10) by 1 = 20
rshift Opération de décalage à droite
$ awk 'BEGIN {
    num1 = 10

    printf "rshift(%d) by 1 = %d\n", num1, rshift(num1, 1)
}'

La sortie est :

rshift(10) by 1 = 5
ou Opération OR bit à bit
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d OR %d) = %d\n", num1, num2, or(num1, num2)
}'

La sortie est :

(10 OR 6) = 14
xor Opération XOR bit à bit
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d XOR %d) = %d\n", num1, num2, xor(num1, num2)
}'

La sortie est :

(10 bitwise xor 6) = 12

Autres fonctions

Nom de la fonction Description Exemple
close(expr) Fermer un fichier ou un pipe
$ awk 'BEGIN {
    cmd = "tr [a-z] [A-Z]"
    print "hello, world !!!" |& cmd
    close(cmd, "to")
    cmd |& getline out
    print out;
    close(cmd);
}'

La sortie est :

HELLO, WORLD !!!
  • La première instruction cmd = "tr [a-z] [A-Z]" établit un canal de communication bidirectionnel dans AWK.
  • La deuxième instruction print fournit l'entrée à la commande tr. &| indique une communication bidirectionnelle.
  • La troisième instruction close(cmd, "to") ferme le processus to une fois l'exécution terminée.
  • La quatrième instruction cmd |& getline out utilise la fonction getline pour stocker la sortie dans la variable out.
  • L'instruction de sortie suivante affiche le contenu de la sortie, et enfin la fonction close ferme cmd.
effacement Utilisé pour supprimer un élément d'un tableau
$ awk 'BEGIN {
    arr[0] = "One"
    arr[1] = "Two"
    arr[2] = "Three"
    arr[3] = "Four"

    print "Array elements before delete operation:"
    for (i in arr) {
        print arr[i]
    }

    delete arr[0]
    delete arr[1]

    print "Array elements after delete operation:"
    for (i in arr) {
        print arr[i]
    }
}'

La sortie est :

Array elements before delete operation:
One
Two
Three
Four

Array elements after delete operation:
Three
Four
exit Met fin à l'exécution du script ; il peut accepter un argument facultatif expr pour transmettre le statut de retour d'AWK.
$ awk 'BEGIN {
    print "Hello, World !!!"

    exit 10

    print "AWK never executes this statement."
}'

La sortie est :

Hello, World !!!
flush Vider le tampon d'un fichier ouvert ou d'un pipe  
getline Lire la ligne suivante

Utiliser getline pour lire une ligne du fichier marks.txt et l'afficher :

$ awk '{getline; print $0}' marks.txt 

AWK lit une ligne du fichier marks.txt et la stocke dans la variable 0. Dans l'instruction suivante, nous utilisons getline pour lire la ligne suivante. Par conséquent, AWK lit la deuxième ligne et la stocke dans la variable 0. Enfin, AWK utilise print pour afficher le contenu de la deuxième ligne. Ce processus continue jusqu'à la fin du fichier.

next Arrêter le traitement de l'enregistrement courant et passer au traitement de l'enregistrement suivant.

Lorsque le motif correspond avec succès, le programme n'effectue aucune opération :

$ awk '{if ($0 ~/Shyam/) next; print $0}' marks.txt
nextfile Arrêter le traitement du fichier courant et commencer le traitement à partir du premier enregistrement du fichier suivant.

Créez d'abord deux fichiers. Le contenu de file1.txt est le suivant :

file1:str1
file1:str2
file1:str3
file1:str4

Le contenu de file2.txt est le suivant :

file2:str1
file2:str2
file2:str3
file2:str4

Testons maintenant la fonction nextfile.

$ awk '{ if ($0 ~ /file1:str2/) nextfile; print $0 }' file1.txt file2.txt

La sortie est :

file1:str1
file2:str1
file2:str2
file2:str3
file2:str4
return Renvoyer une valeur depuis une fonction définie par l'utilisateur. Notez que si aucune valeur de retour n'est spécifiée, la valeur de retour est indéfinie.

Créez un fichier functions.awk avec le contenu suivant :

function addition(num1, num2)
{
    result = num1 + num2

    return result
}

BEGIN {
    res = addition(10, 20)
    print "10 + 20 = " res
}

Exécutez le fichier :

$ awk -f functions.awk 
10 + 20 = 30
system Exécuter une commande spécifique et renvoyer son code de sortie. Une valeur de retour de 0 indique que la commande a été exécutée avec succès ; une valeur non nulle indique que la commande a échoué.
$ awk 'BEGIN { ret = system("date"); print "Return value = " ret }'

La sortie est :

Sun Dec 21 23:16:07 IST 2014
Return value = 0