Las funciones integradas de AWK incluyen principalmente las siguientes:

Funciones aritméticas

Nombre de función Descripción Ejemplo
atan2( y, x ) Devuelve el arco tangente de y/x.
$ awk 'BEGIN {
  PI = 3.14159265
  x = -10
  y = 10
  result = atan2 (y,x) * 180 / PI;

  printf "The arc tangent for (x=%f, y=%f) is %f degrees\n", x, y, result
}'

El resultado de salida es:

The arc tangent for (x=-10.000000, y=10.000000) is 135.000000 degrees
cos( x ) Devuelve el coseno de x; x está en radianes.
$ awk 'BEGIN {
  PI = 3.14159265
  param = 60
  result = cos(param * PI / 180.0);

  printf "The cosine of %f degrees is %f.\n", param, result
}'

El resultado de salida es:

The cosine of 60.000000 degrees is 0.500000.
sin( x ) Devuelve el seno de x; x está en radianes.
$ awk 'BEGIN {
  PI = 3.14159265
  param = 30.0
  result = sin(param * PI /180)

  printf "The sine of %f degrees is %f.\n", param, result
}'

El resultado de salida es:

The sine of 30.000000 degrees is 0.500000.
exp( x ) Devuelve la función potencia de x.
$ awk 'BEGIN {
  param = 5
  result = exp(param);

  printf "The exponential value of %f is %f.\n", param, result
}'

El resultado de salida es:

The exponential value of 5.000000 is 148.413159.
log( x ) Devuelve el logaritmo natural de x.
$ awk 'BEGIN {
  param = 5.5
  result = log (param)

  printf "log(%f) = %f\n", param, result
}'

El resultado de salida es:

log(5.500000) = 1.704748
sqrt( x ) Devuelve la raíz cuadrada de x.
$ awk 'BEGIN {
  param = 1024.0
  result = sqrt(param)

  printf "sqrt(%f) = %f\n", param, result
}'

El resultado de salida es:

sqrt(1024.000000) = 32.000000
int( x ) Devuelve el valor de x truncado a entero.
$ awk 'BEGIN {
  param = 5.12345
  result = int(param)

  print "Truncated value =", result
}'

El resultado de salida es:

Truncated value = 5
rand( ) Devuelve un número arbitrario n, donde 0 <= n < 1.
$ awk 'BEGIN {
  print "Random num1 =" , rand()
  print "Random num2 =" , rand()
  print "Random num3 =" , rand()
}'

El resultado de salida es:

Random num1 = 0.237788
Random num2 = 0.291066
Random num3 = 0.845814
srand( [Expr] ) Establece el valor semilla de la función rand al valor del parámetro Expr, o si se omite el parámetro Expr, utiliza la hora del día. Devuelve el valor semilla anterior.
$ awk 'BEGIN {
  param = 10

  printf "srand() = %d\n", srand()
  printf "srand(%d) = %d\n", param, srand(param)
}'

El resultado de salida es:

srand() = 1
srand(10) = 1417959587

Funciones de cadenas

Función Descripción Ejemplo
gsub( Ere, Repl, [ In ] ) gsub es la abreviatura de sustitución global (global substitution). Excepto que se reemplazan todos los valores concretos de la expresión regular, se ejecuta exactamente igual que la función sub.
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    gsub("World", "Jerry", str)

    print "String after replacement = " str
}'

El resultado de salida es:

String before replacement = Hello, World
String after replacement = Hello, Jerry
sub(regex,sub,string) La función sub realiza una sustitución de subcadena. Reemplaza la primera aparición de la subcadena por regex. El tercer parámetro es opcional y por defecto es $0.
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    sub("World", "Jerry", str)

    print "String after replacement = " str
}'

El resultado de salida es:

String before replacement = Hello, World
String after replacement = Hello, Jerry
substr(str, start, l) La función substr devuelve la subcadena de la cadena str que comienza en el carácter número start y tiene una longitud de l. Si no se especifica el valor de l, devuelve la subcadena sufijo de str que comienza en el carácter número start.
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

El resultado de salida es:

Substring = Hello
index( String1, String2 ) En la cadena especificada por el parámetro String1 (donde aparece el parámetro especificado por String2), devuelve la posición, numerada desde 1. Si el parámetro String2 no aparece en el parámetro String1, devuelve 0 (cero).
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = index(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

El resultado de salida es:

Substring "Two" found at 5 location.
length [(String)] Devuelve la longitud (en caracteres) de la cadena especificada por el parámetro String. Si no se proporciona el parámetro String, devuelve la longitud de todo el registro (variable de registro $0).
$ awk 'BEGIN {
    str = "Hello, World !!!"

    print "Length = ", length(str)
}'

El resultado de salida es:

Substring "Two" found at 5 location.
blength [(String)] Devuelve la longitud (en bytes) de la cadena especificada por el parámetro String. Si no se proporciona el parámetro String, devuelve la longitud de todo el registro (variable de registro $0).  
substr( String, M, [ N ] ) Devuelve una subcadena con el número de caracteres especificado por el parámetro N. La subcadena se obtiene de la cadena especificada por el parámetro String, comenzando sus caracteres en la posición especificada por el parámetro M. El parámetro M se especifica tomando el primer carácter del parámetro String como número 1. Si no se especifica el parámetro N, la longitud de la subcadena será desde la posición especificada por M hasta el final del parámetro String.
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

El resultado de salida es:

Substring = Hello
match( String, Ere ) En la cadena especificada por el parámetro String (donde aparece la expresión regular extendida especificada por el parámetro Ere), devuelve la posición (en caracteres), numerada desde 1, o si el parámetro Ere no aparece, devuelve 0 (cero). La variable especial RSTART se establece al valor devuelto. La variable especial RLENGTH se establece a la longitud de la cadena coincidente, o a -1 (menos uno) si no se encuentra ninguna coincidencia.
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = match(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

El resultado de salida es:

Substring "Two" found at 5 location.
split( String, A, [Ere] ) Divide el parámetro especificado por el parámetro String en elementos de arreglo A
$ awk 'BEGIN {
    str = "One,Two,Three,Four"

    split(str, arr, ",")

    print "Array contains following values"

    for (i in arr) {
        print arr[i]
    }
}'

El resultado de salida es:

Array contains following values
One
Two
Three
Four
tolower( String ) Devuelve la cadena especificada por el parámetro String, donde cada carácter en mayúscula se cambiará a minúscula. La asignación de mayúsculas y minúsculas está definida por la categoría LC_CTYPE del entorno local actual.
$ awk 'BEGIN {
    str = "HELLO, WORLD !!!"

    print "Lowercase string = " tolower(str)
}'

El resultado de salida es:

Lowercase string = hello, world !!!
toupper( String ) Devuelve la cadena especificada por el parámetro String, donde cada carácter en minúscula se cambiará a mayúscula. La asignación de mayúsculas y minúsculas está definida por la categoría LC_CTYPE del entorno local actual.
$ awk 'BEGIN {
    str = "hello, world !!!"

    print "Uppercase string = " toupper(str)
}'

El resultado de salida es:

Uppercase string = HELLO, WORLD !!!
sprintf(Format, Expr, Expr, . . . ) Formatea la expresión especificada por el parámetro Expr de acuerdo con la cadena de formato de la subrutina printf especificada por el parámetro Format y devuelve la cadena resultante final.
$ awk 'BEGIN {
    str = sprintf("%s", "Hello, World !!!")

    print str
}'

El resultado de salida es:

Hello, World !!!
strtonum(str) strtonum convierte la cadena str a un valor numérico. Si la cadena comienza con 0, se trata como un número octal; si la cadena comienza con 0x o 0X, se trata como un número hexadecimal; de lo contrario, se trata como un número de punto flotante.
$ awk 'BEGIN {
    print "十进制数 = " strtonum("123")
    print "八进制数 = " strtonum("0123")
    print "十六进制数 = " strtonum("0x123")
}'

El resultado de salida es:

十进制数 = 123
八进制数 = 83
十六进制数 = 291

Nota:EreLa parte puede ser una expresión regular.

1. Uso de gsub y sub

$ awk 'BEGIN{info="this is a test2012test!";gsub(/[0-9]+/,"||",info);print info}'
this is a test||test!

2. Búsqueda de cadenas (uso de index)

Se utiliza el operador ternario:expresión ? acción1 : acción2

$ awk 'BEGIN{info="this is a test2012test!";print index(info,"11111")?"ok":"no found";}'
no found
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"is")?"ok":"no found";}'
ok
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"test")?"ok":"no found";}'
ok

3. Búsqueda de coincidencias de expresiones regulares (uso de match)

$ awk 'BEGIN{info="this is a test2012test!";print match(info,/[0-9]+/)?"ok":"no found";}'
ok

4. Extracción de subcadenas (uso de substr)

Comenzando desde el cuarto carácter, extraer una cadena de 10 caracteres de longitud.

$ awk 'BEGIN{info="this is a test2012test!";print substr(info,4,10);}'
s is a tes

5. División de cadenas (uso de split)

$ awk 'BEGIN{info="this is a test";split(info,tA," ");print length(tA);for(k in tA){print k,tA[k];}}'
4
2 is
3 a
4 test
1 this

Dividir info, usando espacios para separar la cadena info en un arreglo dinámico tA. Tenga en cuenta que el bucle for...in de awk es un bucle desordenado. No recorre los índices del arreglo de 1...n, por lo que se debe tener especial cuidado al usarlo.

6. Salida de cadenas formateadas (uso de sprintf)

La cadena de formato incluye dos partes: una parte son caracteres normales, que se emitirán tal cual; la otra parte son caracteres de especificación de formato, que comienzan con%comienza, seguido de uno o varios caracteres de especificación, para determinar el formato del contenido de salida. Se debe tener especial cuidado en que al usarprintfpor defecto no se añade un salto de línea, mientras queprintla función, por defecto, añade al final de cada línea un\nsalto de línea.

Especificador de formato Descripción
%d Entero decimal con signo
%u Entero decimal sin signo
%f Número de punto flotante
%s Cadena
%c Carácter individual
%p Valor de puntero
%e Número de punto flotante en forma exponencial
%x %X Entero sin signo representado en hexadecimal
%o Entero sin signo representado en octal
%g Selecciona automáticamente la representación adecuada
$ awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2345; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.2,7C,174
$  awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2645; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.3,7C,174

Nota:Al observar el valor de salida de n3 anterior, se puede ver que una función bastante inteligente al usar printf es que puede redondear y conservar decimales.

Funciones de tiempo

Nombre de función Descripción Ejemplo
mktime( YYYY MM DD HH MM SS[ DST]) Generar formato de hora
$ awk 'BEGIN {
    print "Number of seconds since the Epoch = " mktime("2014 12 14 30 20 10")
}'

El resultado de salida es:

Number of seconds since the Epoch = 1418604610
strftime([format [, timestamp]]) Salida de hora formateada, convierte la marca de tiempo en una cadena de tiempo.
Para el formato específico, consulte la tabla siguiente.
$ awk 'BEGIN {
    print strftime("Time = %m/%d/%Y %H:%M:%S", systime())
}'

El resultado de salida es:

Time = 12/14/2014 22:08:42
systime() Obtiene la marca de tiempo, devuelve el número entero de segundos desde el 1 de enero de 1970 hasta el momento actual (sin contar años bisiestos).
awk 'BEGIN{now=systime();print now}'

El resultado de salida es:

1343210982

Especificadores de formato de fecha y hora de strftime:

N.º Descripción
%a Abreviatura del día de la semana (Mon-Sun).
%A Nombre completo del día de la semana (Monday-Sunday).
%b Abreviatura del mes (Jan).
%B Nombre completo del mes (January).
%c Fecha y hora locales.
%C La parte del siglo del año, cuyo valor es el año dividido por 100.
%d Fecha decimal (01-31)
%D Equivalente a %m/%d/%y.
%e Fecha, si tiene un solo dígito se rellena con un espacio.
%F Equivalente a %Y-%m-%d, que también es el formato de fecha estándar ISO 8601.
%g El año de la semana estándar ISO8610 módulo 100 (00-99). Por ejemplo, el 1 de enero de 1993 pertenece a la semana 53 de 1992. Por lo tanto, aunque es el día 1 de 1993, su año de semana estándar ISO8601 es 1992. Del mismo modo, aunque el 31 de diciembre de 1973 pertenece a 1973, pertenece a la primera semana de 1994. Por lo tanto, el año de semana estándar ISO8610 del 31 de diciembre de 1973 es 1974 y no 1973.
%G Año completo de la semana del estándar ISO.
%h Equivalente a %b.
%H Hora en formato de 24 horas en decimal (00-23).
%I Hora en formato de 12 horas en decimal (00-12).
%j Día del año (001-366).
%m Mes (01-12).
%M Minutos (00-59).
%n Salto de línea (LF ASCII).
%p Notación de 12 horas (AM/PM).
%r Hora en notación de 12 horas (equivalente a %I:%M:%S %p).
%R Equivalente a %H:%M.
%S Valor de segundos del tiempo (00-60).
%t Tabulador (tab).
%T Equivalente a %H:%M:%S.
%u Día de la semana en número (1-7), 1 es lunes.
%U Semana del año (el primer domingo como inicio de la primera semana), 00-53.
%V Semana del año (el primer lunes como inicio de la primera semana), 01-53.
%w Día de la semana en número (0-6), 0 es domingo.
%W Semana del año en decimal (el primer lunes como inicio de la primera semana), 00-53.
%x Representación de fecha local.
%X Representación de hora local.
%y Año módulo 100.
%Y Año completo en decimal.
%z Zona horaria, en formato +HHMM (por ejemplo, requerido por las cabeceras de tiempo RFC 822 o RFC 1036).
%Z Nombre o abreviatura de la zona horaria; sin salida si la zona horaria es indeterminada.

Funciones de manipulación de bits

Nombre de la función. Descripción. Ejemplo.
and Operación Y a nivel de bits (bitwise AND).
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d AND %d) = %d\n", num1, num2, and(num1, num2)
}'

El resultado es:

(10 AND 6) = 2
compl Complemento a nivel de bits (bitwise NOT).
$ awk 'BEGIN {
    num1 = 10

    printf "compl(%d) = %d\n", num1, compl(num1)
}'

El resultado es:

compl(10) = 9007199254740981
lshift Desplazamiento a la izquierda.
$ awk 'BEGIN {
    num1 = 10

    printf "lshift(%d) by 1 = %d\n", num1, lshift(num1, 1)
}'

El resultado es:

lshift(10) by 1 = 20
rshift Desplazamiento a la derecha.
$ awk 'BEGIN {
    num1 = 10

    printf "rshift(%d) by 1 = %d\n", num1, rshift(num1, 1)
}'

El resultado es:

rshift(10) by 1 = 5
or Operación O a nivel de bits (bitwise OR).
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d OR %d) = %d\n", num1, num2, or(num1, num2)
}'

El resultado es:

(10 OR 6) = 14
xor Operación O exclusiva a nivel de bits (bitwise XOR).
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d XOR %d) = %d\n", num1, num2, xor(num1, num2)
}'

El resultado es:

(10 bitwise xor 6) = 12

Otras funciones

Nombre de la función. Descripción. Ejemplo.
close(expr) Cierra el archivo de la tubería (pipe).
$ awk 'BEGIN {
    cmd = "tr [a-z] [A-Z]"
    print "hello, world !!!" |& cmd
    close(cmd, "to")
    cmd |& getline out
    print out;
    close(cmd);
}'

El resultado es:

HELLO, WORLD !!!
  • La primera declaración cmd = "tr [a-z] [A-Z]" establece un canal de comunicación bidireccional en AWK.
  • La segunda declaración print proporciona entrada al comando tr. &| indica comunicación bidireccional.
  • La tercera declaración close(cmd, "to") cierra el proceso "to" después de completar la ejecución.
  • La cuarta declaración cmd |& getline out usa la función getline para almacenar la salida en la variable out.
  • La siguiente declaración de salida imprime el contenido de la salida, y finalmente la función close cierra cmd.
delete Se utiliza para eliminar elementos de un array.
$ awk 'BEGIN {
    arr[0] = "One"
    arr[1] = "Two"
    arr[2] = "Three"
    arr[3] = "Four"

    print "Array elements before delete operation:"
    for (i in arr) {
        print arr[i]
    }

    delete arr[0]
    delete arr[1]

    print "Array elements after delete operation:"
    for (i in arr) {
        print arr[i]
    }
}'

El resultado es:

Array elements before delete operation:
One
Two
Three
Four

Array elements after delete operation:
Three
Four
exit Termina la ejecución del script; puede aceptar un parámetro opcional expr para pasar el estado de retorno de AWK.
$ awk 'BEGIN {
    print "Hello, World !!!"

    exit 10

    print "AWK never executes this statement."
}'

El resultado es:

Hello, World !!!
flush Vacía el búfer de un archivo o tubería abiertos.  
getline Lee la siguiente línea.

Usa getline para leer una línea del archivo marks.txt y mostrarla:

$ awk '{getline; print $0}' marks.txt 

AWK lee una línea del archivo marks.txt y la almacena en la variable 0. En la siguiente declaración, usamos getline para leer la siguiente línea. Por lo tanto, AWK lee la segunda línea y la almacena en 0. Finalmente, AWK usa print para mostrar el contenido de la segunda línea. Este proceso continúa hasta el final del archivo.

next Detiene el procesamiento del registro actual y pasa al procesamiento del siguiente registro.

Cuando el patrón coincide, el programa no realiza ninguna acción:

$ awk '{if ($0 ~/Shyam/) next; print $0}' marks.txt
nextfile Detiene el procesamiento del archivo actual y comienza a procesar desde el primer registro del siguiente archivo.

Primero creamos dos archivos. El contenido de file1.txt es el siguiente:

file1:str1
file1:str2
file1:str3
file1:str4

El contenido del archivo file2.txt es el siguiente:

file2:str1
file2:str2
file2:str3
file2:str4

Ahora probemos la función nextfile.

$ awk '{ if ($0 ~ /file1:str2/) nextfile; print $0 }' file1.txt file2.txt

El resultado es:

file1:str1
file2:str1
file2:str2
file2:str3
file2:str4
return Devuelve un valor desde una función definida por el usuario. Tenga en cuenta que si no se especifica un valor de retorno, el valor de retorno no está definido.

Cree el archivo functions.awk, con el siguiente contenido:

function addition(num1, num2)
{
    result = num1 + num2

    return result
}

BEGIN {
    res = addition(10, 20)
    print "10 + 20 = " res
}

Ejecute el archivo:

$ awk -f functions.awk 
10 + 20 = 30
system Ejecuta un comando específico y devuelve su estado de salida. Un valor de retorno de 0 indica que el comando se ejecutó con éxito; distinto de 0 indica que falló.
$ awk 'BEGIN { ret = system("date"); print "Return value = " ret }'

El resultado es:

Sun Dec 21 23:16:07 IST 2014
Return value = 0