AWK 組み込み関数には主に以下のものがあります:

算術関数

関数名 説明 例
atan2( y, x ) y/x の逆正接を返します。
$ awk 'BEGIN {
  PI = 3.14159265
  x = -10
  y = 10
  result = atan2 (y,x) * 180 / PI;

  printf "The arc tangent for (x=%f, y=%f) is %f degrees\n", x, y, result
}'

出力結果は次のとおりです:

The arc tangent for (x=-10.000000, y=10.000000) is 135.000000 degrees
cos( x ) x の余弦を返します。x はラジアンです。
$ awk 'BEGIN {
  PI = 3.14159265
  param = 60
  result = cos(param * PI / 180.0);

  printf "The cosine of %f degrees is %f.\n", param, result
}'

出力結果は次のとおりです:

The cosine of 60.000000 degrees is 0.500000.
sin( x ) x の正弦を返します。x はラジアンです。
$ awk 'BEGIN {
  PI = 3.14159265
  param = 30.0
  result = sin(param * PI /180)

  printf "The sine of %f degrees is %f.\n", param, result
}'

出力結果は次のとおりです:

The sine of 30.000000 degrees is 0.500000.
exp( x ) x の冪関数を返します。
$ awk 'BEGIN {
  param = 5
  result = exp(param);

  printf "The exponential value of %f is %f.\n", param, result
}'

出力結果は次のとおりです:

The exponential value of 5.000000 is 148.413159.
log( x ) x の自然対数を返します。
$ awk 'BEGIN {
  param = 5.5
  result = log (param)

  printf "log(%f) = %f\n", param, result
}'

出力結果は次のとおりです:

log(5.500000) = 1.704748
sqrt( x ) x の平方根を返します。
$ awk 'BEGIN {
  param = 1024.0
  result = sqrt(param)

  printf "sqrt(%f) = %f\n", param, result
}'

出力結果は次のとおりです:

sqrt(1024.000000) = 32.000000
int( x ) x を整数に切り捨てた値を返します。
$ awk 'BEGIN {
  param = 5.12345
  result = int(param)

  print "Truncated value =", result
}'

出力結果は次のとおりです:

Truncated value = 5
rand( ) 0 <= n < 1 の任意の数 n を返します。
$ awk 'BEGIN {
  print "Random num1 =" , rand()
  print "Random num2 =" , rand()
  print "Random num3 =" , rand()
}'

出力結果は次のとおりです:

Random num1 = 0.237788
Random num2 = 0.291066
Random num3 = 0.845814
srand( [Expr] ) rand 関数のシード値を Expr パラメータの値に設定します。Expr パラメータを省略した場合は、ある日の時刻を使用します。以前のシード値を返します。
$ awk 'BEGIN {
  param = 10

  printf "srand() = %d\n", srand()
  printf "srand(%d) = %d\n", param, srand(param)
}'

出力結果は次のとおりです:

srand() = 1
srand(10) = 1417959587

文字列関数

関数 説明 例
gsub( Ere, Repl, [ In ] ) gsub はグローバル置換(global substitution)の略です。正規表現のすべての具体的な値が置き換えられる点を除いて、sub 関数とまったく同じように実行されます。
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    gsub("World", "Jerry", str)

    print "String after replacement = " str
}'

出力結果は次のとおりです:

String before replacement = Hello, World
String after replacement = Hello, Jerry
sub(regex,sub,string) sub 関数は一度だけ部分文字列の置換を実行します。最初に出現する部分文字列を regex で置き換えます。3 番目のパラメータは省略可能で、デフォルトは $0 です。
$ awk 'BEGIN {
    str = "Hello, World"

    print "String before replacement = " str

    sub("World", "Jerry", str)

    print "String after replacement = " str
}'

出力結果は次のとおりです:

String before replacement = Hello, World
String after replacement = Hello, Jerry
substr(str, start, l) substr 関数は、str 文字列の start 番目の文字から始まる長さ l の部分文字列を返します。l の値が指定されていない場合、str の start 番目の文字から始まる末尾の部分文字列を返します。
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

出力結果は次のとおりです:

Substring = Hello
index( String1, String2 ) String1 パラメータで指定された文字列(その中に String2 で指定されたパラメータが現れる)において、1 から始まる位置を返します。String2 パラメータが String1 パラメータに現れない場合は、0(ゼロ)を返します。
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = index(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

出力結果は次のとおりです:

Substring "Two" found at 5 location.
length [(String)] String パラメータで指定された文字列の長さ(文字単位)を返します。String パラメータが指定されていない場合は、レコード全体の長さ($0 レコード変数)を返します。
$ awk 'BEGIN {
    str = "Hello, World !!!"

    print "Length = ", length(str)
}'

出力結果は次のとおりです:

Substring "Two" found at 5 location.
blength [(String)] String パラメータで指定された文字列の長さ(バイト単位)を返します。String パラメータが指定されていない場合は、レコード全体の長さ($0 レコード変数)を返します。  
substr( String, M, [ N ] ) N パラメータで指定された文字数を持つ部分文字列を返します。部分文字列は String パラメータで指定された文字列から取得され、その文字は M パラメータで指定された位置から始まります。M パラメータでは、String パラメータの最初の文字を番号 1 とします。N パラメータが指定されていない場合、部分文字列の長さは、M パラメータで指定された位置から String パラメータの末尾までの長さになります。
$ awk 'BEGIN {
    str = "Hello, World !!!"
    subs = substr(str, 1, 5)

    print "Substring = " subs
}'

出力結果は次のとおりです:

Substring = Hello
match( String, Ere ) String パラメータで指定された文字列(Ere パラメータで指定された拡張正規表現が出現する場所)において、1 から始まる位置(文字単位)を返します。Ere パラメータが出現しない場合は 0(ゼロ)を返します。RSTART 特殊変数は戻り値に設定されます。RLENGTH 特殊変数はマッチした文字列の長さに設定され、マッチが見つからない場合は -1(マイナス 1)に設定されます。
$ awk 'BEGIN {
    str = "One Two Three"
    subs = "Two"

    ret = match(str, subs)

    printf "Substring \"%s\" found at %d location.\n", subs, ret
}'

出力結果は次のとおりです:

Substring "Two" found at 5 location.
split( String, A, [Ere] ) String パラメータで指定されたパラメータを配列要素 A
$ awk 'BEGIN {
    str = "One,Two,Three,Four"

    split(str, arr, ",")

    print "Array contains following values"

    for (i in arr) {
        print arr[i]
    }
}'

出力結果は次のとおりです:

Array contains following values
One
Two
Three
Four
tolower( String ) String パラメータで指定された文字列を返し、その文字列内のすべての大文字を小文字に変換します。大文字と小文字の対応は、現在のロケールの LC_CTYPE カテゴリによって定義されます。
$ awk 'BEGIN {
    str = "HELLO, WORLD !!!"

    print "Lowercase string = " tolower(str)
}'

出力結果は次のとおりです:

Lowercase string = hello, world !!!
toupper( String ) String パラメータで指定された文字列を返し、その文字列内のすべての小文字を大文字に変換します。大文字と小文字の対応は、現在のロケールの LC_CTYPE カテゴリによって定義されます。
$ awk 'BEGIN {
    str = "hello, world !!!"

    print "Uppercase string = " toupper(str)
}'

出力結果は次のとおりです:

Uppercase string = HELLO, WORLD !!!
sprintf(Format, Expr, Expr, . . . ) Format パラメータで指定された printf サブルーチンのフォーマット文字列に従って、Expr パラメータで指定された式をフォーマットし、最終的に生成された文字列を返します。
$ awk 'BEGIN {
    str = sprintf("%s", "Hello, World !!!")

    print str
}'

出力結果は次のとおりです:

Hello, World !!!
strtonum(str) strtonum は文字列 str を数値に変換します。文字列が 0 で始まる場合は 8 進数として扱います。文字列が 0x または 0X で始まる場合は 16 進数として扱います。それ以外の場合は浮動小数点数として扱います。
$ awk 'BEGIN {
    print "十进制数 = " strtonum("123")
    print "八进制数 = " strtonum("0123")
    print "十六进制数 = " strtonum("0x123")
}'

出力結果は次のとおりです:

十进制数 = 123
八进制数 = 83
十六进制数 = 291

注:Ere部分は正規表現にすることができます。

1、gsub、sub の使用

$ awk 'BEGIN{info="this is a test2012test!";gsub(/[0-9]+/,"||",info);print info}'
this is a test||test!

2、文字列の検索(index の使用)

三項演算子を使用しています:式 ? アクション1 : アクション2

$ awk 'BEGIN{info="this is a test2012test!";print index(info,"11111")?"ok":"no found";}'
no found
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"is")?"ok":"no found";}'
ok
$ awk 'BEGIN{info="this is a test2012test!";print index(info,"test")?"ok":"no found";}'
ok

3、正規表現マッチング検索(match の使用)

$ awk 'BEGIN{info="this is a test2012test!";print match(info,/[0-9]+/)?"ok":"no found";}'
ok

4、部分文字列の切り出し(substr の使用)

4 番目の文字から始めて、長さ 10 の文字列を切り出します。

$ awk 'BEGIN{info="this is a test2012test!";print substr(info,4,10);}'
s is a tes

5、文字列の分割(split の使用)

$ awk 'BEGIN{info="this is a test";split(info,tA," ");print length(tA);for(k in tA){print k,tA[k];}}'
4
2 is
3 a
4 test
1 this

info を分割し、info 文字列をスペースで動的配列 tA に分割します。awk の for...in ループは順序が保証されないループであることに注意してください。配列の添字 1...n の順にはならないため、使用時には特に注意が必要です。

6、文字列のフォーマット出力(sprintf の使用)

このうち、フォーマット文字列は 2 つの部分から構成されます。1 つは通常の文字で、これらの文字はそのまま出力されます。もう 1 つはフォーマット指定文字で、%始まり、その後に 1 つまたは複数の規定文字が続き、出力内容のフォーマットを決定します。特に注意が必要なのは、使用printf時、デフォルトでは改行されません。一方、print関数はデフォルトで各行の末尾に\n改行文字を追加します。

フォーマット指定子 説明
%d 10 進符号付き整数
%u 10 進符号なし整数
%f 浮動小数点数
%s 文字列
%c 単一文字
%p ポインタの値
%e 指数形式の浮動小数点数
%x %X 符号なし 16 進数で表される整数
%o 符号なし 8 進数で表される整数
%g 自動的に適切な表現を選択します
$ awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2345; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.2,7C,174
$  awk 'BEGIN{n1=124.113;n2=-1.224;n3=1.2645; printf("%.2f,%.2u,%.2g,%X,%o\n",n1,n2,n3,n1,n1);}'
124.11,4294967295,1.3,7C,174

注:上記の n3 の出力値を見るとわかるように、printf を使用して処理する際の比較的スマートな機能は、四捨五入して小数点以下の桁数を保持できることです。

時間関数

関数名 説明 例
mktime( YYYY MM DD HH MM SS[ DST]) 時間フォーマットの生成
$ awk 'BEGIN {
    print "Number of seconds since the Epoch = " mktime("2014 12 14 30 20 10")
}'

出力結果は次のとおりです:

Number of seconds since the Epoch = 1418604610
strftime([format [, timestamp]]) 時間をフォーマットして出力し、タイムスタンプを時間文字列に変換します
具体的なフォーマットは下表を参照してください。
$ awk 'BEGIN {
    print strftime("Time = %m/%d/%Y %H:%M:%S", systime())
}'

出力結果は次のとおりです:

Time = 12/14/2014 22:08:42
systime() タイムスタンプを取得し、1970 年 1 月 1 日から現在時刻までの(うるう年を除く)整数秒数を返します
awk 'BEGIN{now=systime();print now}'

出力結果は次のとおりです:

1343210982

strftime の日付と時刻のフォーマット指定子:

番号 説明
%a 曜日の略称(Mon-Sun)。
%A 曜日のフルネーム(Monday-Sunday)。
%b 月の略称(Jan)。
%B 月のフルネーム(January)。
%c ローカルの日付と時刻。
%C 年の世紀部分。その値は年を 100 で割った整数です。
%d 10 進数の日(01-31)
%D %m/%d/%y と同等です。
%e 日付。1 桁の場合はスペースで補完されます。
%F %Y-%m-%d と同等です。これは ISO 8601 標準の日付フォーマットでもあります。
%g ISO8610 標準週の属する年を 100 で割った余り(00-99)。たとえば、1993 年 1 月 1 日は 1992 年の第 53 週に属します。したがって、1993 年の第 1 日ですが、その ISO8601 標準週の属する年は 1992 です。同様に、1973 年 12 月 31 日は 1973 年に属しますが、1994 年の第 1 週に属します。したがって、1973 年 12 月 31 日の ISO8610 標準週の属する年は 1974 であり、1973 ではありません。
%G ISO 標準週が属する年のフル表記。
%h %b と同等。
%H 10進数で表す24時間形式の時(00-23)
%I 10進数で表す12時間形式の時(00-12)
%j 1年のうちの通算日(001-366)
%m 月(01-12)
%M 分(00-59)
%n 改行文字(ASCII LF)
%p 12時間表記(AM/PM)
%r 12時間表記の時刻(%I:%M:%S %p と同等)。
%R %H:%M と同等。
%S 時刻の秒の値(00-60)
%t タブ文字(tab)
%T %H:%M:%S と同等。
%u 数字で表す曜日(1-7)、1は月曜日。
%U 1年のうちの週番号(最初の日曜日を第1週の開始とする)、00-53
%V 1年のうちの週番号(最初の月曜日を第1週の開始とする)、01-53。
%w 数字で表す曜日(0-6)、0は日曜日。
%W 10進数で表す1年のうちの週番号(最初の月曜日を第1週の開始とする)、00-53。
%x ローカルの日付表現
%X ローカルの時刻表現
%y 年を100で割った余り。
%Y 10進数で表す完全な年。
%z タイムゾーン。+HHMM 形式で表します(例:RFC 822 または RFC 1036 の時刻ヘッダーを生成する場合の形式)
%Z タイムゾーン名または略称。タイムゾーンが未確定の場合は出力されません。

ビット操作関数

関数名 説明 例
and ビット論理積(AND)演算。
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d AND %d) = %d\n", num1, num2, and(num1, num2)
}'

出力結果は次のとおりです:

(10 AND 6) = 2
compl ビット単位の補数。
$ awk 'BEGIN {
    num1 = 10

    printf "compl(%d) = %d\n", num1, compl(num1)
}'

出力結果は次のとおりです:

compl(10) = 9007199254740981
lshift 左シフト演算
$ awk 'BEGIN {
    num1 = 10

    printf "lshift(%d) by 1 = %d\n", num1, lshift(num1, 1)
}'

出力結果は次のとおりです:

lshift(10) by 1 = 20
rshift 右シフト演算
$ awk 'BEGIN {
    num1 = 10

    printf "rshift(%d) by 1 = %d\n", num1, rshift(num1, 1)
}'

出力結果は次のとおりです:

rshift(10) by 1 = 5
or ビット論理和(OR)演算
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d OR %d) = %d\n", num1, num2, or(num1, num2)
}'

出力結果は次のとおりです:

(10 OR 6) = 14
xor ビット排他的論理和(XOR)演算
$ awk 'BEGIN {
    num1 = 10
    num2 = 6

    printf "(%d XOR %d) = %d\n", num1, num2, xor(num1, num2)
}'

出力結果は次のとおりです:

(10 bitwise xor 6) = 12

その他の関数

関数名 説明 例
close(expr) パイプのファイルを閉じる
$ awk 'BEGIN {
    cmd = "tr [a-z] [A-Z]"
    print "hello, world !!!" |& cmd
    close(cmd, "to")
    cmd |& getline out
    print out;
    close(cmd);
}'

出力結果は次のとおりです:

HELLO, WORLD !!!
  • 最初のステートメント cmd = "tr [a-z] [A-Z]" は、AWK 内に双方向の通信チャネルを確立します。
  • 2番目のステートメント print は tr コマンドに入力を提供します。&| は双方向通信を表します。
  • 3番目のステートメント close(cmd, "to") は、実行完了後に to プロセスを閉じます。
  • 4番目のステートメント cmd |& getline out は、getline 関数を使用して出力を out 変数に格納します。
  • 次の出力ステートメントは出力内容を出力し、最後に close 関数が cmd を閉じます。
delete 配列から要素を削除するために使用します
$ awk 'BEGIN {
    arr[0] = "One"
    arr[1] = "Two"
    arr[2] = "Three"
    arr[3] = "Four"

    print "Array elements before delete operation:"
    for (i in arr) {
        print arr[i]
    }

    delete arr[0]
    delete arr[1]

    print "Array elements after delete operation:"
    for (i in arr) {
        print arr[i]
    }
}'

出力結果は次のとおりです:

Array elements before delete operation:
One
Two
Three
Four

Array elements after delete operation:
Three
Four
exit スクリプトの実行を終了します。オプションのパラメータ expr を受け取り、AWK の戻り状態を渡すことができます。
$ awk 'BEGIN {
    print "Hello, World !!!"

    exit 10

    print "AWK never executes this statement."
}'

出力結果は次のとおりです:

Hello, World !!!
flush 開いているファイルまたはパイプのバッファをフラッシュします  
getline 次の行を読み込みます

getline を使用してファイル marks.txt から1行読み込み、出力します:

$ awk '{getline; print $0}' marks.txt 

、AWK はファイル marks.txt から1行読み込んで変数 0 に格納します。次のステートメントでは、getline を使用して次の行を読み込みます。したがって、AWK は2行目を読み込んで変数 0 に格納します。最後に、AWK は print を使用して2行目の内容を出力します。この処理はファイルの終端まで続きます。

next 現在のレコードの処理を停止し、次のレコードの処理に移ります。

パターンが正常にマッチした場合、プログラムは何も実行しません:

$ awk '{if ($0 ~/Shyam/) next; print $0}' marks.txt
nextfile 現在のファイルの処理を停止し、次のファイルの最初のレコードから処理を開始します。

まず2つのファイルを作成します。file1.txt の内容は次のとおりです:

file1:str1
file1:str2
file1:str3
file1:str4

ファイル file2.txt の内容は次のとおりです:

file2:str1
file2:str2
file2:str3
file2:str4

それでは nextfile 関数をテストしてみましょう。

$ awk '{ if ($0 ~ /file1:str2/) nextfile; print $0 }' file1.txt file2.txt

出力結果は次のとおりです:

file1:str1
file2:str1
file2:str2
file2:str3
file2:str4
return ユーザー定義関数から値を返します。戻り値が指定されていない場合、戻り値は未定義であることに注意してください。

ファイル functions.awk を作成します。内容は次のとおりです:

function addition(num1, num2)
{
    result = num1 + num2

    return result
}

BEGIN {
    res = addition(10, 20)
    print "10 + 20 = " res
}

このファイルを実行します:

$ awk -f functions.awk 
10 + 20 = 30
system 特定のコマンドを実行し、その終了ステータスを返します。戻り値が 0 の場合はコマンドが正常に実行されたことを示し、0 以外の場合はコマンドの実行に失敗したことを示します。
$ awk 'BEGIN { ret = system("date"); print "Return value = " ret }'

出力結果は次のとおりです:

Sun Dec 21 23:16:07 IST 2014
Return value = 0