В Awk есть несколько очень мощных встроенных переменных. Вообще говоря, они делятся на два типа: - Первый тип — переменные, которые можно изменять, например разделитель полей (FS) и разделитель записей (RS) - Второй тип можно использовать для обработки данных или обобщения данных, например номер записи (NR) и номер поля (NF). В этой статье представлены:FS,OFS, RS, ORS, NR, NR, FNR

FS: переменная разделителя полей ввода

FS(разделитель полей) При чтении и разборе каждой строки во входном файле по умолчанию она разбивается по пробелам на переменные полей, $1, $2 и т. д.FSЭта переменная используется для установки символа-разделителя полей для каждой записи.FSЭто может быть любая строка или регулярное выражение. Вы можете объявить FS следующими двумя способами:

Используйте-Fопцию командной строки

использование его в качестве обычного присваивания переменной

语法:

$ awk -F 'FS' 'commands' inputfilename

或者

$ awk 'BEGIN{FS="FS";}'

FSЭто может быть любой символ или регулярное выражение.

FSЕго можно изменять несколько раз, но он остаётся неизменным до тех пор, пока не будет явно изменён. Однако, если вы хотите изменить разделитель полей, лучше всего изменить его перед чтением текста,FSчтобы изменение вступило в силу для прочитанного текста.

Ниже приведён пример использованияFSдля чтения /etc/passwd с:в качестве разделителя

$ cat etc_passwd.awk
BEGIN{
FS=":";
print "Name\tUserID\tGroupID\tHomeDirectory";
}
{
    print $1"\t"$3"\t"$4"\t"$6;
}
END {
    print NR,"Records Processed";
}

Вывод:

$ awk -f etc_passwd.awk /etc/passwd
Name    UserID  GroupID        HomeDirectory
gnats    41    41    /var/lib/gnats
libuuid    100    101    /var/lib/libuuid
syslog    101    102    /home/syslog
hplip    103    7    /var/run/hplip
avahi    105    111    /var/run/avahi-daemon
saned    110    116    /home/saned
pulse    111    117    /var/run/pulse
gdm    112    119    /var/lib/gdm
8 Records Processed

OFS: переменная разделителя полей вывода

OFS(разделитель полей вывода) эквивалентенFSFS на выходе. По умолчанию в качестве разделителя вывода используется пробел. Ниже приведён примерOFS:

$ awk -F':' '{print $3,$4;}' /etc/passwd
41 41
100 101
101 102
103 7
105 111
110 116
111 117
112 119

Обратите внимание, что запятая в операторе print в команде означает использование пробела для соединения двух параметров, что является значением OFS по умолчанию. ПоэтомуOFSего можно вставить между полями вывода, как показано ниже:

$ awk -F':' 'BEGIN{OFS="=";} {print $3,$4;}' /etc/passwd
41=41
100=101
101=102
103=7
105=111
110=116
111=117
112=11

RS: разделитель записей

RS(разделитель записей) определяет строку записи. При чтении файла по умолчанию одна строка рассматривается как одна запись. В следующем примере student.txt используется в качестве входного файла, записи разделены двумя пустыми строками, а каждое поле каждой записи разделено символом новой строки:

$ cat student.txt
Jones
2143
78
84
77

Gondrol
2321
56
58
45

RinRao
2122
38
37
65

Edwin
2537
78
67
45

Dayan
2415
30
47
20

Тогда следующий скрипт выведет две записи из student.txt:

$ cat student.awk
BEGIN {
    RS="\n\n";
    FS="\n";
}
{
    print $1,$2;
}
$ awk -f student.awk  student.txt
Jones 2143
Gondrol 2321
RinRao 2122
Edwin 2537
Dayan 2415

В student.awk подробная информация о каждом студенте рассматривается как одна запись, потому что RS (разделитель записей) установлен в два символа новой строки. А посколькуFS(разделитель полей) — это символ новой строки, то одна строка — это одно поле.

ORS: переменная разделителя записей вывода

ORS(разделитель записей вывода), как следует из названия, эквивалентенRSRS для вывода. Каждая запись при выводе будет разделена разделителем. См. следующий пример сORS:

$  awk 'BEGIN{ORS="=";} {print;}' student-marks
Jones 2143 78 84 77=Gondrol 2321 56 58 45=RinRao 2122 38 37 65=Edwin 2537 78 67 45=Dayan 2415 30 47 20=

В приведённом выше скрипте каждая запись входного файла=разделена. Примечание: student-marks — это вывод выше.

NR: переменная количества записей

NR(Number of Record) указывает общее количество уже обработанных записей или номер строки (не обязательно в одном файле; файлов может быть несколько). В приведённом ниже примереNRобозначает номер строки; в части END,NR— это общее количество всех записей в файлах.

$ awk '{print "Processing Record - ",NR;}END {print NR, "Students Records are processed";}' student-marks
Processing Record -  1
Processing Record -  2
Processing Record -  3
Processing Record -  4
Processing Record -  5
5 Students Records are processed

NF: количество полей в записи

NF(Number for Field) указывает количество полей в записи. Это очень полезно для определения того, существуют ли все поля в определённой записи. Рассмотрим файл student-mark, как показано ниже:

$ cat student-marks
Jones 2143 78 84 77
Gondrol 2321 56 58 45
RinRao 2122 38 37
Edwin 2537 78 67 45
Dayan 2415 30 47

Затем следующая программа Awk выводит номер записи (NR) и количество полей в этой записи: Поэтому очень легко обнаружить, какие данные отсутствуют.

$ awk '{print NR,"->",NF}' student-marks
1 -> 5
2 -> 5
3 -> 4
4 -> 5
5 -> 4

FILENAME: имя текущего входного файла

FILENAMEобозначает имя файла, читаемого в данный момент. AWK может принимать и читать много файлов для обработки. См. следующий пример:

$ awk '{print FILENAME}' student-marks
student-marks
student-marks
student-marks
student-marks
student-marks

Имя выводится для каждой записи во входном файле.

FNR: количество записей в текущем входном файле

Когда awk читает несколько файлов,NRпредставляет общее количество записей по всем текущим входным файлам, тогда какFNR— количество записей в текущем файле. Как в следующем примере:

$ awk '{print FILENAME, "FNR= ", FNR,"  NR= ", NR}' student-marks bookdetails
student-marks FNR=  1   NR=  1
student-marks FNR=  2   NR=  2
student-marks FNR=  3   NR=  3
student-marks FNR=  4   NR=  4
student-marks FNR=  5   NR=  5
bookdetails FNR=  1   NR=  6
bookdetails FNR=  2   NR=  7
bookdetails FNR=  3   NR=  8
bookdetails FNR=  4   NR=  9
bookdetails FNR=  5   NR=  10

Примечание: bookdetails и student-marks имеют одинаковое содержимое и используются как пример. Можно увидеть разницу междуNRиFNR.

Часто используютсяNRиFNRвместе для обработки двух файлов. Например, есть два файла:

$ cat a.txt
李四|000002
张三|000001
王五|000003
赵六|000004

$ cat b.txt
000001|10
000001|20
000002|30
000002|15
000002|45
000003|40
000003|25
000004|60

Если вы хотите установить соответствие, например Zhang San|000001|10

$ awk -F '|' 'NR == FNR{a[$2]=$1;} NR>FNR {print a[$1],"|", $0}' a.txt b.txt
张三 | 000001|10
张三 | 000001|20
李四 | 000002|30
李四 | 000002|15
李四 | 000002|45
王五 | 000003|40
王五 | 000003|25
赵六 | 000004|60

Английский оригинал: http://www.thegeekstuff.com/2010/01/8-powerful-awk-built-in-variables-fs-ofs-rs-ors-nr-nf-filename-fnr/

Перевод: http://shomy.top/2016/05/05/trans-8-powerful-awk-built-in-variables/