Awk tiene varias variables integradas muy potentes. Generalmente, se dividen en dos tipos de variables integradas: - El primer tipo son variables definidas que pueden cambiarse, como el separador de campos (FS) y el separador de registros (RS) - El segundo tipo puede usarse para procesamiento de datos o resumen de datos, como el número de registros (NR) y el número de campos (NF). El artículo presenta:FS,OFS, RS, ORS, NR, NR, FNR

FS: variable del separador de campos de entrada

FS(Field Separator) Al leer y analizar cada línea del archivo de entrada, por defecto se separa por espacios en variables de campo, $1, $2, etc.FSLa variable se usa para establecer el símbolo separador de campos de cada registro.FSPuede ser cualquier cadena o expresión regular. Puedes declarar FS de las siguientes dos maneras:

Usando-Fla opción de comando

Usarla como variable ordinaria.

语法:

$ awk -F 'FS' 'commands' inputfilename

或者

$ awk 'BEGIN{FS="FS";}'

FSPuede ser cualquier carácter o expresión regular.

FSSe puede cambiar varias veces, pero permanecerá igual hasta que se modifique explícitamente. Sin embargo, si se desea cambiar el separador de campos, es mejor cambiarlo antes de leer el texto,FSpara que el cambio tenga efecto en el texto que se lee.

A continuación hay un ejemplo de usoFSpara leer /etc/passwd con:como separador:

$ cat etc_passwd.awk
BEGIN{
FS=":";
print "Name\tUserID\tGroupID\tHomeDirectory";
}
{
    print $1"\t"$3"\t"$4"\t"$6;
}
END {
    print NR,"Records Processed";
}

Resultado:

$ awk -f etc_passwd.awk /etc/passwd
Name    UserID  GroupID        HomeDirectory
gnats    41    41    /var/lib/gnats
libuuid    100    101    /var/lib/libuuid
syslog    101    102    /home/syslog
hplip    103    7    /var/run/hplip
avahi    105    111    /var/run/avahi-daemon
saned    110    116    /home/saned
pulse    111    117    /var/run/pulse
gdm    112    119    /var/lib/gdm
8 Records Processed

OFS: variable del separador de campos de salida

OFS(Output Field Separator) Es equivalente a FS en la salidaFS, por defecto se usa un carácter de espacio como separador de salida. A continuación hay un ejemploOFSde OFS:

$ awk -F':' '{print $3,$4;}' /etc/passwd
41 41
100 101
101 102
103 7
105 111
110 116
111 117
112 119

Observa que la coma en la instrucción print indica que se usa un espacio para concatenar dos argumentos, que es el valor predeterminado de OFS. Por lo tanto,OFSpuede insertarse entre los campos de salida de la siguiente manera:

$ awk -F':' 'BEGIN{OFS="=";} {print $3,$4;}' /etc/passwd
41=41
100=101
101=102
103=7
105=111
110=116
111=117
112=11

RS: separador de registros

RS(Record Separator) Define una línea como registro. Al leer un archivo, por defecto cada línea se toma como un registro. El siguiente ejemplo usa student.txt como archivo de entrada, los registros están separados por dos líneas en blanco, y cada campo de cada registro está separado por un salto de línea:

$ cat student.txt
Jones
2143
78
84
77

Gondrol
2321
56
58
45

RinRao
2122
38
37
65

Edwin
2537
78
67
45

Dayan
2415
30
47
20

Entonces el siguiente script generará dos elementos desde student.txt:

$ cat student.awk
BEGIN {
    RS="\n\n";
    FS="\n";
}
{
    print $1,$2;
}
$ awk -f student.awk  student.txt
Jones 2143
Gondrol 2321
RinRao 2122
Edwin 2537
Dayan 2415

En student.awk, la información detallada de cada estudiante se toma como un registro, esto se debe a que RS (separador de registros) está configurado como dos saltos de línea. Y porqueFSel separador de campos es un salto de línea, por lo que una línea es un campo.

ORS: variable del separador de registros de salida

ORS(Output Record Separator) Como su nombre lo indica, es equivalente a RS en la salidaRS. Cada registro se separa con un separador en la salida. Vea el siguienteORSejemplo de ORS:

$  awk 'BEGIN{ORS="=";} {print;}' student-marks
Jones 2143 78 84 77=Gondrol 2321 56 58 45=RinRao 2122 38 37 65=Edwin 2537 78 67 45=Dayan 2415 30 47 20=

En el script anterior, cada registro del archivo de entrada se=separa. Nota: student-marks es la salida anterior.

NR: variable del número de registro

NR(Number of Record) Indica el número total de registros procesados, o el número de línea (no necesariamente de un solo archivo, puede ser de varios). En el siguiente ejemplo,NRrepresenta el número de línea; en la parte END,NRes el número total de registros en el archivo.

$ awk '{print "Processing Record - ",NR;}END {print NR, "Students Records are processed";}' student-marks
Processing Record -  1
Processing Record -  2
Processing Record -  3
Processing Record -  4
Processing Record -  5
5 Students Records are processed

NF: número de campos de un registro

NF(Number for Field) Indica el número de campos de un registro. Es muy útil para determinar si todos los campos están presentes en un registro. Observemos el archivo student-mark a continuación:

$ cat student-marks
Jones 2143 78 84 77
Gondrol 2321 56 58 45
RinRao 2122 38 37
Edwin 2537 78 67 45
Dayan 2415 30 47

Luego, el siguiente programa Awk imprime el número de registro (NR), y el número de campos de ese registro: Por lo tanto, se puede descubrir muy fácilmente qué datos faltan.

$ awk '{print NR,"->",NF}' student-marks
1 -> 5
2 -> 5
3 -> 4
4 -> 5
5 -> 4

FILENAME: nombre del archivo de entrada actual

FILENAMERepresenta el nombre del archivo que se está leyendo actualmente. AWK puede aceptar la lectura de muchos archivos para procesar. Vea el siguiente ejemplo:

$ awk '{print FILENAME}' student-marks
student-marks
student-marks
student-marks
student-marks
student-marks

En cada registro de los archivos de entrada se mostrará ese nombre.

FNR: número de registros del archivo de entrada actual

Cuando awk lee varios archivos,NRNR representa el número total de registros de todos los archivos de entrada actuales, mientras queFNRFNR es el número de registros del archivo actual. Como en el siguiente ejemplo:

$ awk '{print FILENAME, "FNR= ", FNR,"  NR= ", NR}' student-marks bookdetails
student-marks FNR=  1   NR=  1
student-marks FNR=  2   NR=  2
student-marks FNR=  3   NR=  3
student-marks FNR=  4   NR=  4
student-marks FNR=  5   NR=  5
bookdetails FNR=  1   NR=  6
bookdetails FNR=  2   NR=  7
bookdetails FNR=  3   NR=  8
bookdetails FNR=  4   NR=  9
bookdetails FNR=  5   NR=  10

Nota: bookdetails y student-marks tienen el mismo contenido, como ejemplo. Se puede verNRyFNRla diferencia.

A menudo se usanNRyFNRen combinación para procesar dos archivos. Por ejemplo, hay dos archivos:

$ cat a.txt
李四|000002
张三|000001
王五|000003
赵六|000004

$ cat b.txt
000001|10
000001|20
000002|30
000002|15
000002|45
000003|40
000003|25
000004|60

Si se quiere hacer la correspondencia, por ejemplo, Zhang San|000001|10

$ awk -F '|' 'NR == FNR{a[$2]=$1;} NR>FNR {print a[$1],"|", $0}' a.txt b.txt
张三 | 000001|10
张三 | 000001|20
李四 | 000002|30
李四 | 000002|15
李四 | 000002|45
王五 | 000003|40
王五 | 000003|25
赵六 | 000004|60

Texto original en inglés: http://www.thegeekstuff.com/2010/01/8-powerful-awk-built-in-variables-fs-ofs-rs-ors-nr-nf-filename-fnr/

Traducción: http://shomy.top/2016/05/05/trans-8-powerful-awk-built-in-variables/