Awk possède plusieurs variables intégrées très puissantes. De manière générale, elles sont divisées en deux types : - Le premier type correspond aux variables qui peuvent être modifiées, comme le séparateur de champs (FS) et le séparateur d'enregistrements (RS) - Le second type peut être utilisé pour le traitement ou la synthèse des données, comme le numéro d'enregistrement (NR) et le numéro de champ (NF). Cet article présente :FS,OFS, RS, ORS, NR, NR, FNR

FS : variable du séparateur de champs d'entrée

FS(séparateur de champs) Lors de la lecture et de l'analyse de chaque ligne du fichier d'entrée, par défaut, elle est divisée par des espaces en variables de champ, $1, $2, etc.FSLa variable est utilisée pour définir le symbole de séparation des champs pour chaque enregistrement.FSIl peut s'agir de n'importe quelle chaîne ou expression régulière. Vous pouvez déclarer FS des deux manières suivantes :

Utilisez-Fl'option de ligne de commande

en l'utilisant comme une affectation de variable ordinaire

语法:

$ awk -F 'FS' 'commands' inputfilename

或者

$ awk 'BEGIN{FS="FS";}'

FSIl peut s'agir de n'importe quel caractère ou expression régulière.

FSIl peut être modifié plusieurs fois, mais reste inchangé jusqu'à ce qu'il soit explicitement modifié. Toutefois, si vous souhaitez modifier le séparateur de champs, il est préférable de le modifier avant de lire le texte,FSafin que la modification prenne effet sur le texte que vous lisez.

Voici un exemple d'utilisation deFSpour lire /etc/passwd avec:comme séparateur

$ cat etc_passwd.awk
BEGIN{
FS=":";
print "Name\tUserID\tGroupID\tHomeDirectory";
}
{
    print $1"\t"$3"\t"$4"\t"$6;
}
END {
    print NR,"Records Processed";
}

Sortie :

$ awk -f etc_passwd.awk /etc/passwd
Name    UserID  GroupID        HomeDirectory
gnats    41    41    /var/lib/gnats
libuuid    100    101    /var/lib/libuuid
syslog    101    102    /home/syslog
hplip    103    7    /var/run/hplip
avahi    105    111    /var/run/avahi-daemon
saned    110    116    /home/saned
pulse    111    117    /var/run/pulse
gdm    112    119    /var/lib/gdm
8 Records Processed

OFS : variable de séparation des champs de sortie

OFS(séparateur de champs de sortie) est équivalent àFSFS en sortie. Par défaut, un caractère espace est utilisé comme séparateur de sortie. Voici unOFSexemple :

$ awk -F':' '{print $3,$4;}' /etc/passwd
41 41
100 101
101 102
103 7
105 111
110 116
111 117
112 119

Notez que la virgule dans l'instruction print de la commande signifie utiliser un espace pour relier deux paramètres, ce qui est la valeur OFS par défaut. Par conséquent,OFSil peut être inséré entre les champs de sortie comme indiqué ci-dessous :

$ awk -F':' 'BEGIN{OFS="=";} {print $3,$4;}' /etc/passwd
41=41
100=101
101=102
103=7
105=111
110=116
111=117
112=11

RS : séparateur d'enregistrements

RS(séparateur d'enregistrements) définit une ligne d'enregistrement. Lors de la lecture d'un fichier, par défaut, une ligne est traitée comme un enregistrement. L'exemple suivant utilise student.txt comme fichier d'entrée, avec des enregistrements séparés par deux lignes vides, et chaque champ de chaque enregistrement séparé par un saut de ligne :

$ cat student.txt
Jones
2143
78
84
77

Gondrol
2321
56
58
45

RinRao
2122
38
37
65

Edwin
2537
78
67
45

Dayan
2415
30
47
20

Ensuite, le script suivant produira deux enregistrements à partir de student.txt :

$ cat student.awk
BEGIN {
    RS="\n\n";
    FS="\n";
}
{
    print $1,$2;
}
$ awk -f student.awk  student.txt
Jones 2143
Gondrol 2321
RinRao 2122
Edwin 2537
Dayan 2415

Dans student.awk, les informations détaillées de chaque étudiant sont traitées comme un seul enregistrement, car RS (séparateur d'enregistrements) est défini sur deux sauts de ligne. Et commeFS(séparateur de champs) est un saut de ligne, une ligne correspond à un champ.

ORS : variable de séparation des enregistrements de sortie

ORS(Output Record Separator), comme son nom l'indique, est équivalent àRSRS pour la sortie. Chaque enregistrement sera séparé par un séparateur lors de la sortie. Voir l'exempleORSsuivant :

$  awk 'BEGIN{ORS="=";} {print;}' student-marks
Jones 2143 78 84 77=Gondrol 2321 56 58 45=RinRao 2122 38 37 65=Edwin 2537 78 67 45=Dayan 2415 30 47 20=

Dans le script ci-dessus, chaque enregistrement du fichier d'entrée est=séparé. Remarque : student-marks est la sortie ci-dessus.

NR : variable du nombre d'enregistrements

NR(Nombre d'enregistrements) indique le nombre total d'enregistrements déjà traités, ou le numéro de ligne (pas nécessairement d'un seul fichier ; il peut y en avoir plusieurs). Dans l'exemple ci-dessous,NRil représente le numéro de ligne ; dans la partie END,NRil s'agit du nombre total de tous les enregistrements dans les fichiers.

$ awk '{print "Processing Record - ",NR;}END {print NR, "Students Records are processed";}' student-marks
Processing Record -  1
Processing Record -  2
Processing Record -  3
Processing Record -  4
Processing Record -  5
5 Students Records are processed

NF : nombre de champs dans un enregistrement

NF(Nombre de champs) indique le nombre de champs dans un enregistrement. Il est très utile pour déterminer si tous les champs existent dans un certain enregistrement. Regardons le fichier student-mark comme suit :

$ cat student-marks
Jones 2143 78 84 77
Gondrol 2321 56 58 45
RinRao 2122 38 37
Edwin 2537 78 67 45
Dayan 2415 30 47

Ensuite, le programme Awk suivant affiche le numéro d'enregistrement (NR), et le nombre de champs dans cet enregistrement : il est donc très facile de découvrir quelles données sont manquantes.

$ awk '{print NR,"->",NF}' student-marks
1 -> 5
2 -> 5
3 -> 4
4 -> 5
5 -> 4

FILENAME : nom du fichier d'entrée actuel

FILENAMEReprésente le nom du fichier en cours de lecture. AWK peut accepter et lire de nombreux fichiers pour traitement. Voir l'exemple suivant :

$ awk '{print FILENAME}' student-marks
student-marks
student-marks
student-marks
student-marks
student-marks

Le nom est affiché pour chaque enregistrement du fichier d'entrée.

FNR : nombre d'enregistrements dans le fichier d'entrée actuel

Lorsqu'awk lit plusieurs fichiers,NRreprésente le nombre total d'enregistrements parmi tous les fichiers d'entrée actuels, tandis queFNRest le nombre d'enregistrements dans le fichier courant. Comme dans l'exemple suivant :

$ awk '{print FILENAME, "FNR= ", FNR,"  NR= ", NR}' student-marks bookdetails
student-marks FNR=  1   NR=  1
student-marks FNR=  2   NR=  2
student-marks FNR=  3   NR=  3
student-marks FNR=  4   NR=  4
student-marks FNR=  5   NR=  5
bookdetails FNR=  1   NR=  6
bookdetails FNR=  2   NR=  7
bookdetails FNR=  3   NR=  8
bookdetails FNR=  4   NR=  9
bookdetails FNR=  5   NR=  10

Remarque : bookdetails et student-marks ont le même contenu, utilisés comme exemple. On peut voir, avecNRetFNR, la différence.

On utilise souventNRetFNRen combinaison pour traiter deux fichiers. Par exemple, il y a deux fichiers :

$ cat a.txt
李四|000002
张三|000001
王五|000003
赵六|000004

$ cat b.txt
000001|10
000001|20
000002|30
000002|15
000002|45
000003|40
000003|25
000004|60

Si vous voulez établir une correspondance, par exemple Zhang San|000001|10

$ awk -F '|' 'NR == FNR{a[$2]=$1;} NR>FNR {print a[$1],"|", $0}' a.txt b.txt
张三 | 000001|10
张三 | 000001|20
李四 | 000002|30
李四 | 000002|15
李四 | 000002|45
王五 | 000003|40
王五 | 000003|25
赵六 | 000004|60

Original anglais : http://www.thegeekstuff.com/2010/01/8-powerful-awk-built-in-variables-fs-ofs-rs-ors-nr-nf-filename-fnr/

Traduction : http://shomy.top/2016/05/05/trans-8-powerful-awk-built-in-variables/