Julia メタプログラミング

Julia は自身のコードを言語内のデータ構造として表現するので、プログラムを操作するプログラムを書くことができます。

メタプログラミングは、コードを生成できるコードを書くことと簡単に理解することもできます。

メタプログラミング(英語: Metaprogramming)とは、ある種のコンピュータプログラムの作成を指します。このようなコンピュータプログラムは、他のプログラム(または自身)をデータとして作成または操作したり、コンパイル時に本来実行時に行うべき作業の一部を実行したりします。ほとんどの場合、すべてのコードを手作業で書くことと比較して、プログラマーはより高い作業効率を得ることができ、あるいは再コンパイルせずに新しい状況に対処するためのより大きな柔軟性をプログラムに与えることができます。

メタプログラムを書く言語をメタ言語と呼びます。操作されるプログラムの言語を「ターゲット言語」と呼びます。あるプログラミング言語が同時に自身のメタ言語でもある能力を「リフレクション(反射)」または「自己反映」と呼びます。

-- ウィキペディア

Julia ソースコードの実行段階

1、生の Julia コードを解析する: Julia パーサーはまず文字列を解析して抽象構文木(AST)を取得します。AST は、操作しやすい形式で全てのコードを含む構造です。

2、解析された Julia コードを実行する:: この段階では、解析された Julia コードを実行します。

対話型プログラミング環境(REPL)でコードを入力して Enter キーを押すと、上記の2つの段階が実行されます。

メタプログラミングツールを使用すると、これら2つの段階の間の Julia コード、つまりソースコードの解析後かつ実行前にアクセスできます。

プログラムの表現

Julia は Meta クラスを提供しており、Meta.parse(str) で文字列を解析し、typeof(e1) で Expr を返すことができます:

例

julia> prog = "1 + 1"
"1 + 1"
julia> ex1 = Meta.parse(prog)
:(1 + 1)

julia> typeof(ex1)
Expr

戻り値:(1 + 1)この戻り値はコロンと後続の式から構成され、typeof(ex1) で Expr が返されます。

Expr オブジェクトは2つの部分を含みます(ex1 は head と args 属性を含みます):

1つは式の型を識別するシンボルオブジェクトです。

例

julia> ex1.head
:call

もう1つは式の引数で、シンボル、他の式、またはリテラルの場合があります:

例

julia> ex1.args
3-element Vector{Any}:
  :+
 1
 1

式は Expr を使って直接構築することもできます:

例

julia> ex2 = Expr(:call, :+, 1, 1)
:(1 + 1)

上で構築した2つの式:1つは解析によって構築され、もう1つは直接構築されたものですが、この2つは等価です:

例

julia> ex1 == ex2
true

Expr オブジェクトはネストすることもできます:

例

julia> ex3 = Meta.parse("(4 + 4) / 2")
:((4 + 4) / 2)

Meta.show_sexpr を使って式を表示することもできます。以下の例はネストされた Expr を示しています:

例

julia> Meta.show_sexpr(ex3)
(:call, :/, (:call, :+, 4, 4), 2)

シンボル

私たちはコロンという:前置演算子を使用して、未評価だが解析済みの式を格納できます。

例

julia> ABC = 100
100

julia> :ABC
:ABC

次の式全体をクォートします:

例

julia> :(100-50)
:(100 - 50)

算術式をクォートします:

例

julia> ex = :(a+b*c+1)
:(a + b * c + 1)

julia> typeof(ex)
Expr

同等の式は Meta.parse を使用するか、Expr で直接構築することもできることに注意してください:

例

julia>      :(a + b*c + 1)       ==
       Meta.parse("a + b*c + 1") ==
       Expr(:call, :+, :a, Expr(:call, :*, :b, :c), 1)
true

複数の式をクォートすることも、quote ... endコードブロックを含めることができます。

例

julia> ex = quote
           x = 1
           y = 2
           x + y
       end
quote
    #= none:2 =#
    x = 1
    #= none:3 =#
    y = 2
    #= none:4 =#
    x + y
end

julia> typeof(ex)
Expr

式の実行

式を解析した後、eval() 関数を使用して実行できます:

例

julia> ex1 = :(1 + 2)
:(1 + 2)

julia> eval(ex1)
3

julia> ex = :(a + b)
:(a + b)

julia> eval(ex)
ERROR: UndefVarError: b not defined
[...]

julia> a = 1; b = 2;

julia> eval(ex)
3

抽象構文木(AST)

抽象構文木 (AST) は構造の一種であり、ソースコードの構文構造の抽象的な表現です。

それはツリー形式でプログラミング言語の構文構造を表現し、ツリーの各ノードはソースコード内の1つの構造を表します。

dump() 関数で式の階層構造を確認できます:

例

julia> dump(:(1 * cos(pi/2)))
Expr
   head: Symbol call
   args: Array{Any}((3,))
      1: Symbol *
      2: Int64 1
      3: Expr
         head: Symbol call
         args: Array{Any}((2,))
            1: Symbol cos
            2: Expr
               head: Symbol call
               args: Array{Any}((3,))
                  1: Symbol /
                  2: Symbol pi
                  3: Int64 2

補間

値パラメータを使用して Expr オブジェクトを直接構築するのは非常に強力ですが、Julia の構文と比較すると、Expr コンストラクタは退屈に感じられるかもしれません。代替方法として、Julia ではリテラルや式をクォートされた式に挿入することができます。式の補間は前置の $ で表されます。

この例では、変数 a の値が挿入されます:

例

julia> a = 1;

julia> ex = :($a + b)
:(1 + b)

クォートされていない式への補間はサポートされておらず、コンパイル時エラーが発生します:

julia> $a + b
ERROR: syntax: "$" expression outside quote

この例では、タプル (1,2,3) が式として条件テストに挿入されます:

julia> ex = :(a in $:((1,2,3)) )
:(a in (1, 2, 3))

式の補間で $ を使用することは、文字列補間やコマンド補間を意図的に連想させます。式の補間により、複雑な Julia 式のプログラム的な構築が便利で読みやすくなります。

宏

マクロは、生成されたコードをプログラムの最終本体に含めるためのメカニズムを提供します。マクロは一連の引数を返された式にマッピングし、生成された式は実行時の eval 呼び出しなしで直接コンパイルされます。マクロの引数には、式、リテラル、シンボルを含めることができます。

これは非常に単純なマクロです:

例

julia> macro sayhello()
           return :( println("Hello, world!") )
       end
@sayhello (macro with 1 method)

マクロは Julia の構文において専用の文字 @ (アットサイン) を持ち、その直後に macro NAME ... end という形式で宣言される一意のマクロ名が続きます。この例では、コンパイラはすべての @sayhello を次のように置き換えます:

:( println("Hello, world!") )

@sayhello が REPL で入力されると、インタプリタが即座に実行するため、計算後の結果だけが表示されます:

julia> @sayhello()
Hello, world!

次に、もう少し複雑なマクロを考えてみましょう:

例

julia> macro sayhello(name)
 return :( println("Hello, ", $name) )
 end
@sayhello (macro with 1 method)

このマクロは引数 name を受け取ります。@sayhello が現れると、クォートされた式が展開され、引数の値が最終的な式に挿入されます:

例

julia> @sayhello("human")
Hello, human

関数 macroexpand を使用して、クォートされた返された式を確認できます:

例

julia> ex = macroexpand(Main, :(@sayhello("human")) )
:(Main.println("Hello, ", "human"))

julia> typeof(ex)
Expr

リテラル "human" が式に挿入されていることがわかります。

マクロ @ macroexpand もあり、これは macroexpand 関数よりも便利かもしれません:

例

julia> @macroexpand @sayhello "human"
:(println("Hello, ", "human"))
その他の拡張