Julia 配列

配列とは、同じデータ型の要素を一定の順序で並べた集合であり、1次元配列と多次元配列があります。

Julia は配列データ構造をサポートしており、サイズが固定されておらず、型が同じ場合も異なる場合もある順序付きコレクションを格納できます。

Julia の配列は可変型のコレクションであり、リスト、ベクトル、テーブル、行列に使用されます。

Julia の配列のインデックスキーは整数で表すことができ、配列のサイズは固定されていません。

Julia は配列を操作するための多くの関数を提供しています。例えば、配列への要素の追加、配列の結合などです。

Julia の配列は角括弧[...]で指定し、複数の要素はカンマ,で区切ります。

1次元配列(つまりベクトル)を作成する構文は次のとおりです:

[A, B, C, ...]

1次元配列の作成

次の例では、単純な1次元配列を作成しています:

例

julia> arr = [1,2,3]
3-element Vector{Int64}:
 1
 2
 3

上記の例では、3つの要素を含む1次元配列を作成しました。各要素は64ビット整数であり、この1次元配列は変数arrにバインドされています。

配列の要素の型は異なっていても構いません:

例

julia> arr =[1, "サンプル", 2.5, pi]
4-element Vector{Any}:
 1
  "サンプル"
 2.5
 π = 3.1415926535897...

上記の例では、異なる型の4つの要素を含む1次元配列を作成しました。piは定数ですπ、各要素は64ビット整数であり、この1次元配列は変数arrにバインドされています。

もちろん、型を強制的に指定することもできます:

例

julia> arr = Int64[1,2,3]
3-element Vector{Int64}:
 1
 2
 3
julia> arr2 = String["Taobao","サンプル","GOOGLE"]
3-element Vector{String}:
 "Taobao"
 "サンプル"
 "GOOGLE"

上記の例の配列arrは整数のみに制限され、arr2は文字列のみに制限されます。

空の配列を作成することもできます:

例

julia> arr = Int64[]
Int64[]

julia> arr2 = String[]
String[]

作成した配列はインデックス値を使用して直接アクセスできます。最初の値のインデックスは1(0ではありません)、2番目の値のインデックスは2、といった具合で、最後の値はendで表すことができます。

例

julia> arr = Int64[1,2,3]
3-element Vector{Int64}:
 1
 2
 3

julia> arr[2]
2
julia> arr2 = String["Taobao","サンプル","GOOGLE"]
3-element Vector{String}:
 "Taobao"
 "サンプル"
 "GOOGLE"

julia> arr2[1]
"Taobao"

julia> arr2[end]
"GOOGLE"

配列の型と次元の指定

次の構文を使用して配列の型と次元を指定することもできます:

Array{type}(undef, dims...)

undefは配列が未初期化であることを示します。

dims...次元の単一タプルでも、次元を可変引数として渡す場合の値のセットでも構いません。

dims...数値は要素数を表し、複数の次元はカンマ,で区切ります。

例

julia> array = Array{Int64}(undef, 3)    # 1次元配列を表し、配列には3つの要素があります
3-element Vector{Int64}:
 4834342704
 4377305096
          0

julia> array = Array{Int64}(undef, 3, 3, 3)    # 3次元配列を表し、各次元の配列には3つの要素があります
3×3×3 Array{Int64, 3}:
[:, :, 1] =
 4562265712  0  0
          1  0  0
          0  0  0

[:, :, 2] =
 0  0  0
 0  0  0
 0  0  0

[:, :, 3] =
 0  0  0
 0  0  0
 0  0  0

上記の例では、配列の型は中括弧の中に置きます。{}、undef は配列を既知の値で初期化しないように設定するために使用され、これが出力で乱数が得られる理由です。


2次元配列と行列の作成

配列要素のカンマを,省略するか、2つのコロンを使用して;;、これで2次元配列を作成できます。例は次のとおりです:

例

julia> [1 2 3 4]
1×4 Matrix{Int64}:
 1  2  3  4
julia> [1;; 2;; 3;; 4]
1×4 Matrix{Int64}:
 1  2  3  4

注意:最初の行に出力される1×4 Matrix{Int64}:、1x4 は1行4列の行列を表します。

1行だけでも2次元配列です。なぜなら Julia は列ベクトルしか認めず、いわゆる行ベクトルは認めないからです。

別の行を追加するには、セミコロンを追加するだけで;、次の例を見てください:

例

julia> [1 2; 3 4]
2×2 Matrix{Int64}:
 1  2
 3  4

コロンと:スペースを使用して実装することもできます 、次の例を見てください:

例

julia> [1:2  3:4]
2×2 Matrix{Int64}:
 1  3
 2  4

注意:最初の行に出力される2×2 Matrix{Int64}:、2×2 は2行2列の行列を表します。

角括弧の中に[]長さが同じ複数の1次元配列を埋め込み、スペースで区切って2次元配列を作成することもできます。

例

julia> [[1,2] [3,4] [5,6]]
2×3 Matrix{Int64}:
 1  3  5
 2  4  6

2x32行3列の配列を表します。

次に、セミコロンと;スペースを柔軟に使用して、 2行3列と3行2列の2次元配列を作成します。

例

julia> [[1;2] [3;4] [5;6]]
2×3 Matrix{Int64}:
 1  3  5
 2  4  6

julia> [[1 2]; [3 4]; [5 6]]
3×2 Matrix{Int64}:
 1  2
 3  4
 5  6

範囲関数を使用した配列の作成

省略記号 ...

省略記号を使用して...配列を作成できます。例は次のとおりです:

例

julia> [0:10...]
11-element Vector{Int64}:
  0
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10

collect() 関数

collect() 関数の構文は次のとおりです:

collect(start:step:stop)

start は開始値、step はステップ幅、stop は終了値です。

この関数は配列を返します。

次の例では、値は1、ステップは2、終了値は13です:

例

julia> collect(1:2:13)
7-element Vector{Int64}:
  1
  3
  5
  7
  9
 11
 13

collect() 関数は型を指定することもできます。構文は次のとおりです:

collect(element_type, start:step:stop)

次の例では、浮動小数点型の配列を作成します:

例

julia> collect(Float64, 1:2:5)
3-element Vector{Float64}:
 1.0
 3.0
 5.0

range() 関数

range() 関数は範囲を生成し、ステップ幅を指定できます。collect() 関数の呼び出しに便利です。

range() 関数の構文は次のとおりです:

range(start, stop, length) range(start, stop; length, step) range(start; length, stop, step) range(;start, length, stop, step)

start は開始値、step はステップ幅、stop は終了値、length は長さです。

例

julia> range(1, length=100)
1:100

julia> range(1, stop=100)
1:100

julia> range(1, step=5, length=100)
1:5:496

julia> range(1, step=5, stop=100)
1:5:96

julia> range(1, 10, length=101)
1.0:0.09:10.0

julia> range(1, 100, step=5)
1:5:96

julia> range(stop=10, length=5)
6:10

julia> range(stop=10, step=1, length=5)
6:1:10

julia> range(start=1, step=1, stop=10)
1:1:10

長さ length が指定されておらず、かつstop - startstop が step の整数倍でない場合は、stop の前に終了する範囲が生成されます。

julia> range(1, 3.5, step=2)
1.0:2.0:3.0

range() と collect() を使用した配列の作成:

例

julia> collect(range(1,stop=10))
10-element Vector{Int64}:
  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
julia> collect(range(1, length=15, stop=150))
15-element Vector{Float64}:
   1.0
  11.642857142857142
  22.285714285714285
  32.92857142857143
  43.57142857142857
  54.214285714285715
  64.85714285714286
  75.5
  86.14285714285714
  96.78571428571429
 107.42857142857143
 118.07142857142857
 128.71428571428572
 139.35714285714286
 150.0

内包表記とジェネレータを使用した配列の作成

配列を作成するもう1つの便利な方法は、内包表記を使用することです。

配列の内包表記の構文は次のとおりです:

A = [ F(x,y,...) for x=rx, y=ry, ... ]

F(x,y,...) は、与えられたリスト内の変数 x、y などの各値に対して計算を行います。値は任意の反復可能オブジェクトとして指定できますが、通常は 1:n や 2:(n-1) のような範囲、または [1.2, 3.4, 5.7] のような明示的な配列値です。結果は N 次元の密な配列であり、変数の範囲 rx、ry などの次元を連結してその次元が得られ、F(x,y,...) の各計算はスカラーを返します。

例

julia> [n^2 for n in 1:10]
10-element Vector{Int64}:
   1
   4
   9
  16
  25
  36
  49
  64
  81
 100

2次元配列の作成:

例

julia> [n*m for n in 1:10, m in 1:10]
10×10 Matrix{Int64}:
  1   2   3   4   5   6   7   8   9   10
  2   4   6   8  10  12  14  16  18   20
  3   6   9  12  15  18  21  24  27   30
  4   8  12  16  20  24  28  32  36   40
  5  10  15  20  25  30  35  40  45   50
  6  12  18  24  30  36  42  48  54   60
  7  14  21  28  35  42  49  56  63   70
  8  16  24  32  40  48  56  64  72   80
  9  18  27  36  45  54  63  72  81   90
 10  20  30  40  50  60  70  80  90  100

配列の内包表記は角括弧なしで記述することもでき、その場合はジェネレータと呼ばれるオブジェクトが生成されます。

次の例では、配列を作成します:

例

julia> collect(n^2 for n in 1:5)
5-element Vector{Int64}:
  1
  4
  9
 16
 25

次の式は、メモリを割り当てずにシーケンスの合計を計算します:

例

julia> sum(1/n^2 for n=1:1000)
1.6439345666815615

Julia 配列の基本関数

関数 説明
eltype(A) A内の要素の型
length(A) A内の要素の数
ndims(A) Aの次元数
size(A) を含むA各次元の要素数のタプル
size(A,n) A 第 n次元内の要素数
axes(A) を含むA有効なインデックスのタプル
axes(A,n) 第 n次元の有効なインデックスの範囲
eachindex(A) 内のすべての位置にアクセスするA効率的なイテレータ
stride(A,k) 次元k上の間隔(stride)(隣接する要素間の線形インデックス距離)
strides(A) 各次元上の間隔(stride)を含むタプル

Juliaの構築と初期化

Julia は、配列を構築および初期化するための多くの関数を提供しています。次の関数では、引数 dims ... はタプルで次元を表すことができ、可変長の整数値として次元を指定することもできます。ほとんどの関数の最初の引数は、配列の要素型 T を表します。型 T が省略された場合は、デフォルトで Float64 になります。

関数 説明
Array{T}(undef, dims...) 初期化されていない密な配列Array
zeros(T, dims...) すべてゼロの配列Array
ones(T, dims...) すべての要素が 1 の配列Array
trues(dims...) 各要素がtrueのBitArray
falses(dims...) 各要素がfalseのBitArray
reshape(A, dims...) 同じデータを含むAが、次元の異なる配列
copy(A) コピーA
deepcopy(A) ディープコピー、すなわちコピーA、そしてその要素を再帰的にコピーする
similar(A, T, dims...) と同じA型(ここでは密、疎などを指す)を持つ未初期化配列だが、指定された要素型と次元を持つ。2番目と3番目の引数はどちらも任意であり、省略した場合は要素型とAの次元。
reinterpret(T, A) とA同じバイナリデータを持つ配列だが、要素型はT
rand(T, dims...) ランダムなArray、要素の値は [ 0 , 1 ) [0, 1) 半開区間の一様分布に従い、かつ一次の独立同分布に従う[1]
randn(T, dims...) ランダムなArray、要素は標準正規分布に従い、独立同分布である
Matrix{T}(I, m, n) m 行 n列の単位行列(最初に実行する必要がありますusing LinearAlgebraして初めて使用できるI)
range(start, stop=stop, length=n) からstart 到 stopを持つn個の線形間隔の要素の範囲
fill!(A, x) 値でx配列を埋めるA
fill(x, dims...) 値でx埋められたArray

zeros()配列インスタンスを作成し、要素の初期値はすべて0:

例

julia> zeros(Int8, 2, 3)
2×3 Matrix{Int8}:
 0  0  0
 0  0  0

julia> zeros(Int8, (2, 3))
2×3 Matrix{Int8}:
 0  0  0
 0  0  0

julia> zeros((2, 3))
2×3 Matrix{Float64}:
 0.0  0.0  0.0
 0.0  0.0  0.0
その他の拡張