Julia 複素数と有理数

この章では、Julia の複素数と有理数について学習します。

Julia 言語には、定義済みの複素数および有理数型が含まれており、それらに対するさまざまな標準数学演算と初等関数をサポートしています。

複素数

複素数は実数の拡張であり、任意の多項式方程式が根を持つようにします。

私たちは次のような形のz=a+bi(a、bはともに実数)の数を複素数と呼ぶ。ここで、a を実部、b を虚部、i を虚数単位と呼び、i は次の性質を持つ。z の虚部 b=0 のとき、z は実数である。z の虚部 b≠0 かつ実部 a=0 のとき、z を純虚数と呼ぶことが多い。

グローバル定数 im は複素数 i にバインドされており、-1 の主平方根を表します。

Julia では数値リテラルを数値リテラル係数として使えるので、この結び付けにより、複素数に対して伝統的な数学表記に似た非常に便利な構文が提供されます。

実例

julia> 1+2im
1 + 2im

複素数に対してさまざまな算術演算を行うこともできます。

実例

julia> (1 + 2im)*(2 - 3im)
8 + 1im

julia> (1 + 2im)/(1 - 2im)
-0.6 + 0.8im

julia> (1 + 2im) + (1 - 2im)
2 + 0im

julia> (-3 + 2im) - (5 - 1im)
-8 + 3im

julia> (-1 + 2im)^2
-3 - 4im

julia> (-1 + 2im)^2.5
2.729624464784009 - 6.9606644595719im

julia> (-1 + 2im)^(1 + 1im)
-0.27910381075826657 + 0.08708053414102428im

julia> 3(2 - 5im)
6 - 15im

julia> 3(2 - 5im)^2
-63 - 60im

julia> 3(2 - 5im)^-1.0
0.20689655172413796 + 0.5172413793103449im

型昇格メカニズムにより、異なる型のオペランドの組み合わせを使用することもできます。

実例

julia> 2(1 - 1im)
2 - 2im

julia> (2 + 3im) - 1
1 + 3im

julia> (1 + 2im) + 0.5
1.5 + 2.0im

julia> (2 + 3im) - 0.5im
2.0 + 2.5im

julia> 0.75(1 + 2im)
0.75 + 1.5im

julia> (2 + 3im) / 2
1.0 + 1.5im

julia> (1 - 3im) / (2 + 2im)
-0.5 - 1.0im

julia> 2im^2
-2 + 0im

julia> 1 + 3/4im
1.0 - 0.75im

注意3/4im == 3/(4*im) == -(3/4*im)係数の方が除算よりも優先順位が高いためです。

Julia には複素数を操作するための標準関数がいくつか用意されています。

実例

julia> z = 1 + 2im
1 + 2im

julia> real(1 + 2im) # z の実部
1

julia> imag(1 + 2im) # z の虚部
2

julia> conj(1 + 2im) # z の複素共役
1 - 2im

julia> abs(1 + 2im) # z の絶対値
2.23606797749979

julia> abs2(1 + 2im) # 絶対値の二乗
5

julia> angle(1 + 2im) # ラジアン単位の位相角
1.1071487177940904

慣例により、複素数の絶対値(abs)は零点からの距離です。abs2 は絶対値の二乗を与え、複素数に作用するときに平方根を取らずに済むため非常に便利です。angle はラジアン単位の位相角(偏角関数とも呼ばれます)を返します。他のすべての初等関数も複素数に対して完全に定義されています。

実例

julia> sqrt(1im)
0.7071067811865476 + 0.7071067811865475im

julia> sqrt(1 + 2im)
1.272019649514069 + 0.7861513777574233im

julia> cos(1 + 2im)
2.0327230070196656 - 3.0518977991517997im

julia> exp(1 + 2im)
-1.1312043837568135 + 2.4717266720048188im

julia> sinh(1 + 2im)
-0.4890562590412937 + 1.4031192506220405im

数学関数は通常、実数に適用すると実数値を返し、複素数に適用すると複素数値を返すことに注意してください。例えば、sqrt を -1 と -1 + 0im に適用すると、-1 == -1 + 0im であっても動作が異なります。

実例

julia> sqrt(-1)
ERROR: DomainError with -1.0:
sqrt will only return a complex result if called with a complex argument. Try sqrt(Complex(x)).
Stacktrace:
[...]

julia> sqrt(-1 + 0im)
0.0 + 1.0im

変数から複素数を構築する場合、テキスト型の数値係数表記は使用できません。代わりに、乗算を明示的に記述する必要があります。

実例

julia> a = 1; b = 2; a + b*im
1 + 2im

ただし、この方法は推奨されません。代わりに、より効率的な complex 関数を使用して、実部と虚部から直接複素数値を構築することをお勧めします。

実例

julia> a = 1; b = 2; complex(a, b)
1 + 2im

この構築により、乗算と加算の操作が避けられます。

Inf と NaN は、特別な浮動小数点値の章で説明されているように、複素数の実部と虚部に現れる可能性があります。

実例

julia> 1 + Inf*im
1.0 + Inf*im

julia> 1 + NaN*im
1.0 + NaN*im

有理数

有理数は、整数(正の整数、0、負の整数)と分数の総称であり、整数と分数の集合です。

数学的には、2つの整数の比として表すことができる数(, )は有理数と定義されます。例えば、0.75(次のように表現できます)。整数と分数を総称して有理数と呼びます。有理数と対をなすのは無理数で、例えばは整数の比で表すことができません。

Julia には、整数の正確な比を表す分数型があります。分数は//演算子で構築します:

実例

julia> 2//3
2//3

分数の分子と分母に公約数がある場合、それらは約分されて最も簡単な形になり、分母は非負になります。

実例

julia> 6//9
2//3

julia> -4//8
-1//2

julia> 5//-15
-1//3

julia> -4//-12
1//3

整数比のこの標準化された形式は一意であるため、分数値の等価性は分子と分母が両方とも等しいことを検証することでテストできます。分数値の標準化された分子と分母は、numerator 関数と denominator 関数を使用して取得できます。

実例

julia> numerator(2//3)
2

julia> denominator(2//3)
3

分子と分母を直接比較する必要は通常ありません。標準の算術演算と比較演算は分数値に対しても定義されているためです。

実例

julia> 2//3 == 6//9
true

julia> 2//3 == 9//27
false

julia> 3//7 < 1//2
true

julia> 3//4 > 2//3
true

julia> 2//4 + 1//6
2//3

julia> 5//12 - 1//4
1//6

julia> 5//8 * 3//12
5//32

julia> 6//5 / 10//7
21//25

分数は簡単に浮動小数点数に変換できます。

実例

julia> float(3//4)
0.75

任意の整数値 a と b(a == 0 かつ b == 0 の場合を除く)に対して、分数から浮動小数点数への変換は次の一貫性に従います。

実例

julia> a = 1; b = 2;

julia> isequal(float(a//b), a/b)
true

Julia は無限の分数値の構築を受け付けます:

実例

julia> 5//0
1//0

julia> x = -3//0
-1//0

julia> typeof(x)
Rational{Int64}

ただし、NaN 分数値を構築しようとすることは受け付けません。

実例

julia> 0//0
ERROR: ArgumentError: invalid rational: zero(Int64)//zero(Int64)
Stacktrace:
[...]

いつものように、型昇格システムにより、分数は他の数値型と簡単にやり取りできます。

実例

julia> 3//5 + 1
8//5

julia> 3//5 - 0.5
0.09999999999999998

julia> 2//7 * (1 + 2im)
2//7 + 4//7*im

julia> 2//7 * (1.5 + 2im)
0.42857142857142855 + 0.5714285714285714im

julia> 3//2 / (1 + 2im)
3//10 - 3//5*im

julia> 1//2 + 2im
1//2 + 2//1*im

julia> 1 + 2//3im
1//1 - 2//3*im

julia> 0.5 == 1//2
true

julia> 0.33 == 1//3
false

julia> 0.33 < 1//3
true

julia> 1//3 - 0.33
0.0033333333333332993
その他の拡張