ADO Ускорение скриптов с помощью GetString()


Пожалуйста, используйте метод GetString() для ускорения ваших ASP-скриптов (вместо нескольких строк Response.Write).


Многострочный Response.Write

Следующий пример демонстрирует способ отображения запроса к базе данных в HTML-таблице:

<html>
<body>

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"

set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>

<table border="1" width="100%">
<%do until rs.EOF%>
  <tr>
    <td><%Response.Write(rs.fields("Companyname"))%></td>
    <td><%Response.Write(rs.fields("Contactname"))%></td>
  </tr>
<%rs.MoveNext
loop%>
</table>

<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>

</body>
</html>

При большом запросе это увеличит время обработки скрипта, потому что серверу нужно обработать большое количество команд Response.Write.

Решение состоит в том, чтобы создать всю строку, от <table> до </table>, а затем вывести её — используя Response.Write только один раз.


Метод GetString()

Метод GetString() позволяет нам вывести все строки, используя только один Response.Write. Ему даже не нужен код do..loop или проверки условий для определения, находится ли набор записей в EOF.

Синтаксис

str = rs.GetString(format,rows,coldel,rowdel,nullexpr)

Чтобы создать HTML-таблицу с использованием данных из набора записей, нам нужно использовать только три из вышеуказанных параметров (все параметры необязательны):

  • coldel — HTML, используемый в качестве разделителя столбцов
  • rowdel — HTML, используемый в качестве разделителя строк
  • nullexpr — HTML, используемый, когда столбец пуст

Примечание:Метод GetString() является функцией ADO 2.0. Вы можете скачать ADO 2.0 по следующему адресу:http://www.microsoft.com/data/download.htm

В следующем примере мы будем использовать метод GetString() для сохранения набора записей в виде строки:

Пример

<html>
<body>

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"

set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn

str=rs.GetString(,,"</td><td>","</td></tr><tr><td>","&nbsp;")
%>

<table border="1" width="100%">
  <tr>
    <td><%Response.Write(str)%></td>
  </tr>
</table>

<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

Переменная str выше содержит строку всех столбцов и строк, возвращённых инструкцией SELECT. Между каждым столбцом появляется </td><td>; между каждой строкой появляется </td></tr><tr><td>. Таким образом, используя только один Response.Write, мы получаем требуемый HTML.

Другие расширения