ADO Accélérez les scripts avec GetString()


Veuillez utiliser la méthode GetString() pour accélérer vos scripts ASP (au lieu de plusieurs lignes de Response.Write).


Response.Write multiligne

L'exemple suivant montre une façon d'afficher une requête de base de données dans un tableau HTML :

<html>
<body>

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"

set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn
%>

<table border="1" width="100%">
<%do until rs.EOF%>
  <tr>
    <td><%Response.Write(rs.fields("Companyname"))%></td>
    <td><%Response.Write(rs.fields("Contactname"))%></td>
  </tr>
<%rs.MoveNext
loop%>
</table>

<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>

</body>
</html>

Pour une grande requête, cela augmentera le temps de traitement du script, car le serveur doit traiter un grand nombre de commandes Response.Write.

La solution consiste à créer la chaîne entière, de <table> à </table>, puis à l'afficher - en utilisant Response.Write une seule fois.


Méthode GetString()

La méthode GetString() nous permet d'afficher toutes les chaînes en utilisant un seul Response.Write. Elle n'a même pas besoin de code do..loop ni de tests de condition pour vérifier si le recordset est à EOF.

Syntaxe

str = rs.GetString(format,rows,coldel,rowdel,nullexpr)

Pour créer un tableau HTML à l'aide des données d'un recordset, nous n'avons besoin que de trois des paramètres ci-dessus (tous les paramètres sont facultatifs) :

  • coldel - HTML utilisé comme délimiteur de colonne
  • rowdel - HTML utilisé comme délimiteur de ligne
  • nullexpr - HTML utilisé lorsqu'une colonne est vide

Remarque :La méthode GetString() est une fonctionnalité d'ADO 2.0. Vous pouvez télécharger ADO 2.0 à l'adresse suivante :http://www.microsoft.com/data/download.htm

Dans l'exemple suivant, nous utiliserons la méthode GetString() pour stocker le recordset sous forme de chaîne :

Exemple

<html>
<body>

<%
set conn=Server.CreateObject("ADODB.Connection")
conn.Provider="Microsoft.Jet.OLEDB.4.0"
conn.Open "c:/webdata/northwind.mdb"

set rs = Server.CreateObject("ADODB.recordset")
rs.Open "SELECT Companyname, Contactname FROM Customers", conn

str=rs.GetString(,,"</td><td>","</td></tr><tr><td>","&nbsp;")
%>

<table border="1" width="100%">
  <tr>
    <td><%Response.Write(str)%></td>
  </tr>
</table>

<%
rs.close
conn.close
set rs = Nothing
set conn = Nothing
%>
</body>
</html>

La variable str ci-dessus contient une chaîne de toutes les colonnes et lignes renvoyées par l'instruction SELECT. Entre chaque colonne, </td><td> apparaît ; entre chaque ligne, </td></tr><tr><td> apparaît. Ainsi, en utilisant un seul Response.Write, nous obtenons le HTML requis.

Autres extensions