(fila 2, columna 3; el índice comienza en 0)
El modo de direccionamiento (Addressing Mode) determina cómo la CPU localiza el operando de una instrucción: de dónde provienen los datos y dónde se almacena el resultado.
¿Qué es el modo de direccionamiento?
El operando de cada instrucción en ensamblador puede ser un valor inmediato, un valor en un registro o un dato en memoria.
Modo de direccionamientoEs decir, le indica a la CPU cómo calcular la dirección real del operando o le proporciona directamente el valor del operando.
La arquitectura x86 ofrece múltiples modos de direccionamiento flexibles; comprender el escenario de uso de cada modo es la base para escribir código ensamblador eficiente.
Direccionamiento inmediato (Immediate Addressing)
El operando está incluido directamente en la instrucción y es un valor constante.
El operando fuente es un valor inmediato; la CPU lo lee directamente de la instrucción sin necesidad de acceder a memoria ni a registros.
Ejemplo
mov eax, 42 ; 42 es un valor inmediato, codificado directamente en la instrucción
add ebx, 100 ; 100 es un valor inmediato
mov ecx, 0x2A ; Valor inmediato hexadecimal
mov edx, 'A' ; El carácter 'A' = 0x41, también es un valor inmediato
El direccionamiento inmediato es el "modo de direccionamiento" más rápido, porque los datos están en el flujo de instrucciones y la CPU los obtiene al mismo tiempo que busca la instrucción. Sin embargo, el valor inmediato solo puede ser operando fuente, no operando destino. No se puede escribir
mov 42, eax。
= 7)
El operando se almacena en un registro y la CPU opera directamente sobre el registro.
Este es también uno de los modos de operación más rápidos, porque no hay costo de acceso a memoria.
Ejemplo
mov eax, ebx ; Copia el valor de ebx a eax (ambos operandos son direccionamiento por registro)
add ecx, edx ; ecx = ecx + edx
push eax ; Empuja el valor de eax a la pila
inc ebx ; ebx = ebx + 1
El direccionamiento por registro es el más rápido; al escribir código ensamblador, se debe dar prioridad al uso de registros para almacenar datos de acceso frecuente. Pero la cantidad de registros es limitada; no se pueden meter todos los datos en registros.
Direccionamiento directo (Direct Addressing)
El operando es una dirección de memoria; la dirección se escribe directamente en la instrucción (en forma de etiqueta de variable).
La CPU necesita acceder a la memoria una vez para leer o escribir datos.
Ejemplo
; Ejemplo de direccionamiento directo
section .data
value dd 12345678 ; Define una variable de doble palabra en memoria
name db 'ejemplo', 0
section .text
global _start
_start:
; Leer memoria con direccionamiento directo
mov eax, [value] ; Lee 4 bytes de la dirección de memoria value a eax
; eax ahora es 12345678
; Escribir en memoria con direccionamiento directo
mov dword [value], 98765 ; Escribe 98765 en la dirección de memoria de value
; Leer byte con direccionamiento directo
mov al, [name] ; Lee el primer byte de name, 'r' = 0x72
mov bl, [name + 1] ; Lee el segundo byte de name, 'u' = 0x75
mov eax, 1
mov ebx, 0
int 0x80
Direccionamiento indirecto por registro (Register Indirect Addressing)
En el registro se almacena una dirección de memoria, y la CPU usa esa dirección para acceder a la memoria.
El registro entre corchetes se utiliza como un puntero.
Ejemplo
; Ejemplo de direccionamiento indirecto por registro
section .data
msg db 'Hello, EJEMPLO!', 0xA
len equ $ - msg
section .text
global _start
_start:
mov eax, msg ; Coloca la dirección (puntero) de msg en eax
mov al, [eax] ; Direccionamiento indirecto: lee el byte de memoria apuntado por eax
; Ahora al = 'H' = 0x48
; Recorre la cadena y convierte las letras minúsculas a mayúsculas
mov esi, msg ; esi apunta al inicio de la cadena
mov ecx, len ; ecx contiene la longitud de la cadena
convert_loop:
mov al, [esi] ; Direccionamiento indirecto: lee el carácter apuntado por esi
cmp al, 'a' ; ¿Es mayor o igual que 'a'?
jb next_char ; No, omitir
cmp al, 'z' ; ¿Es menor o igual que 'z'?
ja next_char ; No, omitir
sub al, 32 ; Convertir a mayúscula (en la tabla ASCII, minúscula - mayúscula = 32)
mov [esi], al ; Direccionamiento indirecto: escribe de vuelta en la posición apuntada por esi
next_char:
inc esi ; El puntero se mueve al siguiente carácter
loop convert_loop ; Continuar el bucle hasta procesar todo
; Imprimir la cadena convertida
mov eax, 4
mov ebx, 1
mov ecx, msg
mov edx, len
int 0x80
mov eax, 1
mov ebx, 0
int 0x80
El direccionamiento indirecto es la base para recorrer arreglos, operar con cadenas y acceder a estructuras de datos. ESI y EDI son registros diseñados específicamente para usarse con el direccionamiento indirecto; junto con
inc esise puede recorrer fácilmente memoria contigua.
Direccionamiento base (Base Addressing)
Dirección efectiva = valor del registro base + desplazamiento (offset).
El registro base puede ser EBX, EBP, ESI, EDI, etc.
Ejemplo
section .data
; Simula una estructura simple: {id, age, score}
; id = 2 bytes
; age = 2 bytes
; score = 4 bytes
student db 0x01, 0x00 ; id = 1
db 0x14, 0x00 ; age = 20
dd 95 ; score = 95
section .text
global _start
_start:
mov ebx, student ; ebx contiene la dirección base de la estructura
; Acceso a cada miembro con base + desplazamiento
mov ax, [ebx] ; Lee id (desplazamiento 0)
mov ax, [ebx + 2] ; Lee age (desplazamiento 2)
mov eax, [ebx + 4] ; Lee score (desplazamiento 4)
; Modifica age
mov word [ebx + 2], 21 ; age = 21
; Modifica score
mov dword [ebx + 4], 98 ; score = 98
mov eax, 1
mov ebx, 0
int 0x80
Direccionamiento indexado (Indexed Addressing)
Utiliza un registro índice (ESI o EDI) más un desplazamiento para acceder a los elementos de un arreglo.
Ejemplo
section .data
array dd 10, 20, 30, 40, 50 ; Arreglo de 5 elementos de doble palabra
array_len equ ($ - array) / 4 ; Número de elementos = total de bytes / 4
section .text
global _start
_start:
mov ecx, array_len ; Contador de bucle
mov esi, 0 ; Índice (el subíndice comienza en 0)
mov ebx, 0 ; Suma acumulada
sum_loop:
mov eax, [array + esi * 4] ; Direccionamiento indexado: array + índice * tamaño del elemento
; esi * 4 porque cada elemento ocupa 4 bytes
add ebx, eax ; Acumular en ebx
inc esi ; Incrementa el índice en 1
loop sum_loop
; ebx = 10+20+30+40+50 = 150
; Índice + desplazamiento: acceder al segundo elemento
; array + 2*4 = array + 8, es decir, 30
mov eax, [array + 2*4] ; eax = 30
mov eax, 1
mov ebx, 0
int 0x80
Direccionamiento base-indexado (Base-Indexed Addressing)
Dirección efectiva = registro base + registro índice × factor de escala + desplazamiento.
Este es el modo de direccionamiento más potente de x86, ya que puede realizar el cálculo de la dirección en una sola instrucción.
Nota: x86 solo admite un registro índice × factor de escala; no admite múltiples registros con factor de escala.
Ejemplo
section .data
; Arreglo bidimensional de 3 filas y 4 columnas
matrix dd 1, 2, 3, 4
dd 5, 6, 7, 8
dd 9, 10, 11, 12
section .text
global _start
_start:
; Accede a matrix
; Dirección = matrix + fila * bytes por fila + columna * bytes por elemento
; = matrix + 1*16 + 2*4
; = matrix + 24
mov ebx, matrix ; Registro base
mov esi, 24 ; Desplazamiento total calculado
; Formato correcto: base + desplazamiento
mov eax, [ebx + esi] ; eax = 7
; Formato estándar de direccionamiento base-indexado: [base + índice*factor de escala + desplazamiento]
; Acceso directo al sexto elemento (matrix
mov edi, 6
mov eax, [matrix + edi*4] ; eax = 7
; Salida del programa
mov eax, 1
mov ebx, 0
int 0x80
Resumen de modos de direccionamiento
La siguiente figura muestra completamente los 7 modos de direccionamiento de x86 y su principio de funcionamiento:
| Modo de direccionamiento | Formato de sintaxis | Dirección/valor efectivo | Usos típicos |
|---|---|---|---|
| Direccionamiento inmediato | mov eax, 42 | 42 (valor constante) | Inicialización, operaciones con constantes |
| Direccionamiento por registro | mov eax, ebx | Valor del registro ebx | Transferencia de datos entre registros |
| Direccionamiento directo | mov eax, [var] | Valor en la dirección de memoria var | Acceder a variables globales |
| Direccionamiento indirecto | mov eax, [ebx] | Dirección = valor de ebx | Operaciones con punteros, recorrido de memoria |
| Direccionamiento base | mov eax, [ebx+8] | Dirección = ebx + 8 | Acceso a miembros de estructuras |
| Direccionamiento indexado | mov eax, [arr+esi*4] | Dirección = arr + esi × 4 | Acceso a arrays unidimensionales |
| Direccionamiento base-indexado | mov eax, [ebx+esi*4+8] | Dirección = ebx + esi × 4 + 8 | Arrays bidimensionales, estructuras complejas |
Otras extensionesEn el modo protegido de 32 bits,todos los registros de propósito general pueden usarse como registros base o índiceEsto difiere mucho del modo real de 16 bits (en el modo de 16 bits solo BX, BP, SI, DI se pueden usar para direccionamiento). La flexibilidad de 32 bits hace que el direccionamiento sea más conveniente.